configure.ac

   1 AC_PREREQ([2.69])
   2 AC_INIT([openocd], [0.11.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5 AC_CONFIG_AUX_DIR([.])
   6
   7 m4_include([config_subdir.m4])dnl
   8
   9 # check for makeinfo before calling AM_INIT_AUTOMAKE
  10 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  11 AS_IF([test "x$MAKEINFO" = "x"], [
  12   MAKEINFO='echo makeinfo missing; true'
  13   AC_MSG_WARN([Info documentation will not be built.])
  14 ])
  15 AC_SUBST([MAKEINFO])
  16
  17 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20 AH_BOTTOM([
  21 #include <helper/system.h>
  22 #include <helper/types.h>
  23 #include <helper/replacements.h>
  24 ])
  25
  26 AC_LANG([C])
  27 AC_PROG_CC
  28 # autoconf 2.70 obsoletes AC_PROG_CC_C99 and includes it in AC_PROG_CC
  29 m4_version_prereq([2.70],[],[AC_PROG_CC_C99])
  30 AM_PROG_CC_C_O
  31 AC_PROG_RANLIB
  32 PKG_PROG_PKG_CONFIG([0.23])
  33
  34 dnl disable checks for C++, Fortran and GNU Java Compiler
  35 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  36 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  37 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  38 AC_DISABLE_SHARED
  39 LT_INIT
  40 AC_SUBST([LIBTOOL_DEPS])
  41
  42 dnl configure checks required for Jim files (these are obsolete w/ C99)
  43 AC_C_CONST
  44 AC_TYPE_LONG_LONG_INT
  45
  46 AC_SEARCH_LIBS([ioperm], [ioperm])
  47 AC_SEARCH_LIBS([dlopen], [dl])
  48 AC_SEARCH_LIBS([openpty], [util])
  49
  50 AC_CHECK_HEADERS([sys/socket.h])
  51 AC_CHECK_HEADERS([elf.h])
  52 AC_CHECK_HEADERS([dirent.h])
  53 AC_CHECK_HEADERS([fcntl.h])
  54 AC_CHECK_HEADERS([malloc.h])
  55 AC_CHECK_HEADERS([netdb.h])
  56 AC_CHECK_HEADERS([poll.h])
  57 AC_CHECK_HEADERS([pthread.h])
  58 AC_CHECK_HEADERS([strings.h])
  59 AC_CHECK_HEADERS([sys/ioctl.h])
  60 AC_CHECK_HEADERS([sys/param.h])
  61 AC_CHECK_HEADERS([sys/select.h])
  62 AC_CHECK_HEADERS([sys/stat.h])
  63 AC_CHECK_HEADERS([sys/sysctl.h])
  64 AC_CHECK_HEADERS([sys/time.h])
  65 AC_CHECK_HEADERS([sys/types.h])
  66 AC_CHECK_HEADERS([unistd.h])
  67 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  68 #include <stdio.h>
  69 #ifdef STDC_HEADERS
  70 # include <stdlib.h>
  71 # include <stddef.h>
  72 #else
  73 # ifdef HAVE_STDLIB_H
  74 #  include <stdlib.h>
  75 # endif
  76 #endif
  77 #ifdef HAVE_SYS_SOCKET_H
  78 # include <sys/socket.h>
  79 #endif
  80 ])
  81
  82 AC_HEADER_ASSERT
  83 AC_HEADER_STDBOOL
  84
  85 AC_C_BIGENDIAN
  86
  87 AC_CHECK_FUNCS([strndup])
  88 AC_CHECK_FUNCS([strnlen])
  89 AC_CHECK_FUNCS([gettimeofday])
  90 AC_CHECK_FUNCS([usleep])
  91 AC_CHECK_FUNCS([vasprintf])
  92 AC_CHECK_FUNCS([realpath])
  93
  94 # guess-rev.sh only exists in the repository, not in the released archives
  95 AC_MSG_CHECKING([whether to build a release])
  96 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  97   build_release=no
  98 ], [
  99   build_release=yes
 100 ])
 101 AC_MSG_RESULT([$build_release])
 102
 103 # Adapter drivers
 104 # 1st column -- configure option
 105 # 2nd column -- description
 106 # 3rd column -- symbol used for both config.h and automake
 107 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 108 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 109 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 110 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 111 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 112
 113 m4_define([USB1_ADAPTERS],
 114         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 115         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 116         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 117         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 118         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 119         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 120         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 121         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 122         [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
 123         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 124         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 125         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 126         [[aice], [Andes JTAG Programmer], [AICE]]])
 127
 128 m4_define([USB0_ADAPTERS],
 129         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 130         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 131
 132 m4_define([HIDAPI_ADAPTERS],
 133         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
 134         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 135
 136 m4_define([HIDAPI_USB1_ADAPTERS],
 137         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 138
 139 m4_define([LIBFTDI_ADAPTERS],
 140         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 141         [[presto], [ASIX Presto Adapter], [PRESTO]]])
 142
 143 m4_define([LIBFTDI_USB1_ADAPTERS],
 144         [[[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 145
 146 m4_define([LIBGPIOD_ADAPTERS],
 147         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 148
 149 m4_define([LIBJAYLINK_ADAPTERS],
 150         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 151
 152 m4_define([PCIE_ADAPTERS],
 153         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 154
 155 m4_define([OPTIONAL_LIBRARIES],
 156         [[[capstone], [Use Capstone disassembly framework], []]])
 157
 158 AC_ARG_ENABLE([doxygen-html],
 159   AS_HELP_STRING([--disable-doxygen-html],
 160     [Disable building Doxygen manual as HTML.]),
 161   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 162 AC_SUBST([doxygen_as_html])
 163 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 164 AC_MSG_RESULT([$doxygen_as_html])
 165
 166 AC_ARG_ENABLE([doxygen-pdf],
 167   AS_HELP_STRING([--enable-doxygen-pdf],
 168     [Enable building Doxygen manual as PDF.]),
 169   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 170 AC_SUBST([doxygen_as_pdf])
 171 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 172 AC_MSG_RESULT([$doxygen_as_pdf])
 173
 174 AC_ARG_ENABLE([gccwarnings],
 175   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 176   [gcc_warnings=$enableval], [gcc_warnings=yes])
 177
 178 AC_ARG_ENABLE([wextra],
 179   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 180   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 181
 182 AC_ARG_ENABLE([werror],
 183   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 184   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 185
 186 # set default verbose options, overridden by following options
 187 debug_usb_io=no
 188 debug_usb_comms=no
 189
 190 AC_ARG_ENABLE([verbose],
 191   AS_HELP_STRING([--enable-verbose],
 192       [Enable verbose JTAG I/O messages (for debugging).]),
 193   [
 194   debug_usb_io=$enableval
 195   debug_usb_comms=$enableval
 196   ], [])
 197
 198 AC_ARG_ENABLE([verbose_usb_io],
 199   AS_HELP_STRING([--enable-verbose-usb-io],
 200       [Enable verbose USB I/O messages (for debugging)]),
 201   [debug_usb_io=$enableval], [])
 202
 203 AC_ARG_ENABLE([verbose_usb_comms],
 204   AS_HELP_STRING([--enable-verbose-usb-comms],
 205       [Enable verbose USB communication messages (for debugging)]),
 206   [debug_usb_comms=$enableval], [])
 207
 208 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 209 AC_MSG_RESULT([$debug_usb_io])
 210 AS_IF([test "x$debug_usb_io" = "xyes"], [
 211   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 212 ])
 213
 214 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 215 AC_MSG_RESULT([$debug_usb_comms])
 216 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 217   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 218 ])
 219
 220 debug_malloc=no
 221 AC_ARG_ENABLE([malloc_logging],
 222   AS_HELP_STRING([--enable-malloc-logging],
 223       [Include free space in logging messages (requires malloc.h).]),
 224   [debug_malloc=$enableval], [])
 225
 226 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 227 AC_MSG_RESULT([$debug_malloc])
 228 AS_IF([test "x$debug_malloc" = "xyes"], [
 229   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 230 ])
 231
 232 AC_ARG_ENABLE([dummy],
 233   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 234   [build_dummy=$enableval], [build_dummy=no])
 235
 236 AC_ARG_ENABLE([rshim],
 237   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 238   [build_rshim=$enableval], [build_rshim=no])
 239
 240 m4_define([AC_ARG_ADAPTERS], [
 241   m4_foreach([adapter], [$1],
 242         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 243                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 244                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 245                 [], [ADAPTER_VAR([adapter])=$2])
 246   ])
 247 ])
 248
 249 AC_ARG_ADAPTERS([
 250   USB1_ADAPTERS,
 251   USB0_ADAPTERS,
 252   HIDAPI_ADAPTERS,
 253   HIDAPI_USB1_ADAPTERS,
 254   LIBFTDI_ADAPTERS,
 255   LIBFTDI_USB1_ADAPTERS
 256   LIBGPIOD_ADAPTERS,
 257   LIBJAYLINK_ADAPTERS
 258   ],[auto])
 259
 260 AC_ARG_ENABLE([parport],
 261   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 262   [build_parport=$enableval], [build_parport=no])
 263
 264 AC_ARG_ENABLE([parport_ppdev],
 265   AS_HELP_STRING([--disable-parport-ppdev],
 266       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 267     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 268
 269 AC_ARG_ENABLE([parport_giveio],
 270     AS_HELP_STRING([--enable-parport-giveio],
 271       [Enable use of giveio for parport (for CygWin only)]),
 272     [parport_use_giveio=$enableval], [parport_use_giveio=])
 273
 274 AC_ARG_ENABLE([jtag_vpi],
 275   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 276   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 277
 278 AC_ARG_ENABLE([jtag_dpi],
 279   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 280   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 281
 282 AC_ARG_ENABLE([amtjtagaccel],
 283   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 284   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 285
 286 AS_CASE(["${host_cpu}"],
 287   [arm*|aarch64], [
 288     AC_ARG_ENABLE([bcm2835gpio],
 289       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 290       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 291     AC_ARG_ENABLE([imx_gpio],
 292       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 293       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 294   ],
 295   [
 296     build_bcm2835gpio=no
 297     build_imx_gpio=no
 298 ])
 299
 300 AS_CASE(["${host_cpu}"],
 301   [arm*], [
 302     AC_ARG_ENABLE([ep93xx],
 303       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 304       [build_ep93xx=$enableval], [build_ep93xx=no])
 305
 306     AC_ARG_ENABLE([at91rm9200],
 307       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 308       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 309   ],
 310   [
 311     build_ep93xx=no
 312     build_at91rm9200=no
 313 ])
 314
 315 AC_ARG_ENABLE([gw16012],
 316   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 317   [build_gw16012=$enableval], [build_gw16012=no])
 318
 319 AC_ARG_ENABLE([buspirate],
 320   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 321   [build_buspirate=$enableval], [build_buspirate=no])
 322
 323 AC_ARG_ENABLE([sysfsgpio],
 324   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 325   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 326
 327 AC_ARG_ENABLE([xlnx_pcie_xvc],
 328   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 329   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 330
 331 AS_CASE([$host_os],
 332   [linux*], [],
 333   [
 334     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 335       AC_MSG_ERROR([sysfsgpio is only available on linux])
 336     ])
 337
 338     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 339       AC_MSG_ERROR([linuxgpiod is only available on linux])
 340     ])
 341
 342     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 343       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 344     ])
 345
 346     AS_CASE([$host_os], [freebsd*], [],
 347     [
 348       AS_IF([test "x$build_rshim" = "xyes"], [
 349         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 350       ])
 351     ])
 352 ])
 353
 354 AC_ARG_ENABLE([minidriver_dummy],
 355   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 356   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 357
 358 AC_ARG_ENABLE([internal-jimtcl],
 359   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 360   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 361
 362 AC_ARG_ENABLE([internal-libjaylink],
 363   AS_HELP_STRING([--disable-internal-libjaylink],
 364   [Disable building internal libjaylink]),
 365   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 366
 367 build_minidriver=no
 368
 369 AC_ARG_ENABLE([remote-bitbang],
 370   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 371   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 372
 373 AC_MSG_CHECKING([whether to enable dummy minidriver])
 374 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 375   AS_IF([test "x$build_minidriver" = "xyes"], [
 376     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 377   ])
 378   build_minidriver=yes
 379   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 380   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 381       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 382 ])
 383 AC_MSG_RESULT([$build_minidriver_dummy])
 384
 385 AC_MSG_CHECKING([whether standard drivers can be built])
 386 AS_IF([test "x$build_minidriver" = "xyes"], [
 387   AC_MSG_RESULT([no])
 388   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 389   sleep 2
 390 ], [
 391   AC_MSG_RESULT([yes])
 392 ])
 393
 394 AS_CASE(["${host_cpu}"],
 395   [i?86|x86*], [],
 396   [
 397     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 398       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 399     ])
 400     parport_use_ppdev=yes
 401 ])
 402
 403 AS_CASE([$host],
 404   [*-cygwin*], [
 405     is_win32=yes
 406     parport_use_ppdev=no
 407
 408     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 409       [is_mingw=yes],[is_mingw=no])
 410     AS_IF([test "x$is_mingw" = "xyes"], [
 411       AS_IF([test "x$parport_use_giveio" = "xno"], [
 412         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 413       ])
 414       parport_use_giveio=yes
 415       is_cygwin=no
 416     ], [
 417       is_cygwin=yes
 418       # sys/io.h needed under cygwin for parport access
 419       AS_IF([test "x$build_parport" = "xyes"], [
 420         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 421       ])
 422     ])
 423   ],
 424   [*-mingw* | *-msys*], [
 425     is_mingw=yes
 426     is_win32=yes
 427     parport_use_ppdev=no
 428
 429     AS_IF([test "x$parport_use_giveio" = "xno"], [
 430       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 431     ])
 432     parport_use_giveio=yes
 433
 434     AS_IF([test "x$build_buspirate" = "xyes"], [
 435       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 436     ])
 437
 438     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 439   ],
 440   [*darwin*], [
 441     is_darwin=yes
 442
 443     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 444       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 445     ])
 446     parport_use_giveio=no
 447   ],
 448   [
 449     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 450       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 451     ])
 452     parport_use_giveio=no
 453 ])
 454
 455 AS_IF([test "x$is_cygwin" = "xyes"], [
 456     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 457 ], [
 458     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 459 ])
 460
 461 AS_IF([test "x$is_mingw" = "xyes"], [
 462     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 463 ], [
 464     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 465 ])
 466
 467 AS_IF([test "x$is_win32" = "xyes"], [
 468     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 469 ], [
 470     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 471 ])
 472
 473 AS_IF([test "x$is_darwin" = "xyes"], [
 474     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 475 ], [
 476     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 477 ])
 478
 479 AS_IF([test "x$build_parport" = "xyes"], [
 480   build_bitbang=yes
 481   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 482 ], [
 483   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 484 ])
 485
 486 AS_IF([test "x$build_rshim" = "xyes"], [
 487   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 488 ], [
 489   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 490 ])
 491
 492 AS_IF([test "x$build_dummy" = "xyes"], [
 493   build_bitbang=yes
 494   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 495 ], [
 496   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 497 ])
 498
 499 AS_IF([test "x$build_ep93xx" = "xyes"], [
 500   build_bitbang=yes
 501   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 502 ], [
 503   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 504 ])
 505
 506 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 507   build_bitbang=yes
 508   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 509 ], [
 510   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 511 ])
 512
 513 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 514   build_bitbang=yes
 515   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 516 ], [
 517   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 518 ])
 519
 520 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 521   build_bitbang=yes
 522   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 523 ], [
 524   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 525 ])
 526
 527 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 528   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 529 ], [
 530   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 531 ])
 532
 533 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 534   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 535 ], [
 536   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 537 ])
 538
 539 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 540   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 541 ], [
 542   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 543 ])
 544
 545 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 546   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 547 ], [
 548   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 549 ])
 550
 551
 552 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 553   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 554 ], [
 555   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 556 ])
 557
 558 AS_IF([test "x$build_gw16012" = "xyes"], [
 559   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 560 ], [
 561   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 562 ])
 563
 564 AS_IF([test "x$build_buspirate" = "xyes"], [
 565   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 566 ], [
 567   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 568 ])
 569
 570 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 571   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 572     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 573   ], [
 574     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 575   ])
 576 ])
 577
 578 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 579   build_bitbang=yes
 580   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 581 ], [
 582   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 583 ])
 584
 585 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 586   build_bitbang=yes
 587   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 588 ], [
 589   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 590 ])
 591
 592 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 593   build_xlnx_pcie_xvc=yes
 594   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 595 ], [
 596   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 597 ])
 598
 599 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 600         use_libusb1=yes
 601         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 602         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 603                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 604                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 605         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 606         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 607         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 608                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 609   ], [
 610         use_libusb1=no
 611         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 612 ])
 613
 614 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 615
 616 AC_ARG_WITH([capstone],
 617                 AS_HELP_STRING([--with-capstone], [Use Capstone disassembly library (default=auto)])
 618         , [
 619                 enable_capstone=$withval
 620         ], [
 621                 enable_capstone=auto
 622 ])
 623
 624 AS_IF([test "x$enable_capstone" != xno], [
 625         PKG_CHECK_MODULES([CAPSTONE], [capstone], [
 626                 AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have Capstone disassembly framework.])
 627         ], [
 628                 AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have Capstone disassembly framework.])
 629                 if test "x$enable_capstone" != xauto; then
 630                         AC_MSG_ERROR([--with-capstone was given, but test for Capstone failed])
 631                 fi
 632                 enable_capstone=no
 633         ])
 634 ])
 635
 636 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 637         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 638                 use_hidapi=yes
 639                 break
 640         ],[
 641                 use_hidapi=no
 642         ])
 643 done
 644
 645 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 646         use_libftdi=yes
 647         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 648                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 649   ], [
 650         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 651 ])
 652
 653 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 654
 655 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 656         [use_libjaylink=yes], [use_libjaylink=no])
 657
 658 m4_define([PROCESS_ADAPTERS], [
 659   m4_foreach([adapter], [$1], [
 660         AS_IF([test $2], [
 661                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 662                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 663                 ], [
 664                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 665                 ])
 666         ], [
 667                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 668                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 669                 ])
 670                 ADAPTER_VAR([adapter])=no
 671         ])
 672         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 673   ])
 674 ])
 675
 676 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 677 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 678 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 679 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 680 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 681 PROCESS_ADAPTERS([LIBFTDI_USB1_ADAPTERS], ["x$use_libftdi" = "xyes" -a "x$use_libusb1" = "xyes"], [libftdi and libusb-1.x])
 682 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 683 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 684
 685 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 686   build_bitbang=yes
 687 ])
 688
 689 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 690         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 691         AM_CONDITIONAL([HLADAPTER], [true])
 692 ], [
 693         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 694         AM_CONDITIONAL([HLADAPTER], [false])
 695 ])
 696 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 697 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 698 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 699
 700 AS_IF([test "x$enable_jlink" != "xno"], [
 701   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 702     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 703       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 704                 [--enable-subproject-build])
 705     ], [
 706       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 707     ])
 708   ])
 709 ])
 710
 711 # Presto needs the bitq module
 712 AS_IF([test "x$enable_presto" != "xno"], [
 713   build_bitq=yes
 714 ])
 715
 716 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 717 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 718 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 719 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 720 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 721 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 722 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 723 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 724 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 725 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 726 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 727 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 728 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 729 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 730 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 731 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 732 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 733 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 734 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 735 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 736 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 737 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 738 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 739 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 740 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 741 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 742 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 743 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 744 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 745 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 746 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$enable_capstone" != "xno"])
 747
 748 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 749 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 750
 751 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 752 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 753
 754 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 755 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 756 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 757 #define _GNU_SOURCE
 758 #include <unistd.h>
 759 #include <stdlib.h>
 760   ]], [[char **ep = environ;]]
 761   )], [
 762     AC_MSG_RESULT([yes])
 763     has_environ=yes
 764   ], [
 765     AC_MSG_RESULT([no])
 766
 767     # Possibility #2: can environ be found in an available library?
 768     AC_MSG_CHECKING([for extern environ])
 769     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 770     extern char **environ;
 771     ]], [[char **ep = environ;]]
 772       )], [
 773         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 774         has_environ=yes
 775       ], [
 776         has_environ=no
 777       ])
 778     AC_MSG_RESULT([${has_environ}])
 779   ])
 780
 781 AS_IF([test "x${has_environ}" != "xyes" ], [
 782   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 783 ])
 784
 785 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 786
 787 # set default gcc warnings
 788 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 789 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 790   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 791   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 792   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 793   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 794   GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
 795 ])
 796 AS_IF([test "x${gcc_werror}" = "xyes"], [
 797   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 798 ])
 799
 800 # override default gcc cflags
 801 AS_IF([test "x$gcc_warnings" = "xyes"], [
 802   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 803 ])
 804
 805 AC_SUBST(EXTRA_DIST_NEWS, ["$(echo $srcdir/NEWS-*)"])
 806
 807 AC_CONFIG_FILES([
 808   Makefile
 809 ])
 810 AC_OUTPUT
 811
 812 echo
 813 echo
 814 echo OpenOCD configuration summary
 815 echo --------------------------------------------------
 816 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 817         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 818         LIBFTDI_USB1_ADAPTERS,
 819         LIBGPIOD_ADAPTERS,
 820         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS,
 821         OPTIONAL_LIBRARIES],
 822         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 823         AS_CASE([$ADAPTER_VAR([adapter])],
 824                 [auto], [
 825                         echo "$s"yes '(auto)'
 826                 ],
 827                 [yes], [
 828                         echo "$s"yes
 829                 ],
 830                 [no], [
 831                         echo "$s"no
 832         ])
 833 ])
 834 echo