configure.ac

   1 AC_PREREQ([2.69])
   2 AC_INIT([openocd], [0.11.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5 AC_CONFIG_AUX_DIR([.])
   6
   7 m4_include([config_subdir.m4])dnl
   8
   9 # check for makeinfo before calling AM_INIT_AUTOMAKE
  10 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  11 AS_IF([test "x$MAKEINFO" = "x"], [
  12   MAKEINFO='echo makeinfo missing; true'
  13   AC_MSG_WARN([Info documentation will not be built.])
  14 ])
  15 AC_SUBST([MAKEINFO])
  16
  17 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20 AH_BOTTOM([
  21 #include <helper/system.h>
  22 #include <helper/types.h>
  23 #include <helper/replacements.h>
  24 ])
  25
  26 AC_LANG([C])
  27 AC_PROG_CC
  28 # autoconf 2.70 obsoletes AC_PROG_CC_C99 and includes it in AC_PROG_CC
  29 m4_version_prereq([2.70],[],[AC_PROG_CC_C99])
  30 AM_PROG_CC_C_O
  31 AC_PROG_RANLIB
  32 PKG_PROG_PKG_CONFIG([0.23])
  33
  34 dnl disable checks for C++, Fortran and GNU Java Compiler
  35 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  36 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  37 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  38 AC_DISABLE_SHARED
  39 LT_INIT
  40 AC_SUBST([LIBTOOL_DEPS])
  41
  42 dnl configure checks required for Jim files (these are obsolete w/ C99)
  43 AC_C_CONST
  44 AC_TYPE_LONG_LONG_INT
  45
  46 AC_SEARCH_LIBS([ioperm], [ioperm])
  47 AC_SEARCH_LIBS([dlopen], [dl])
  48 AC_SEARCH_LIBS([openpty], [util])
  49
  50 AC_CHECK_HEADERS([sys/socket.h])
  51 AC_CHECK_HEADERS([elf.h])
  52 AC_EGREP_HEADER(Elf64_Ehdr, [elf.h], [
  53   AC_DEFINE([HAVE_ELF64], [1], [Define to 1 if the system has the type `Elf64_Ehdr'.])
  54 ])
  55 AC_CHECK_HEADERS([dirent.h])
  56 AC_CHECK_HEADERS([fcntl.h])
  57 AC_CHECK_HEADERS([malloc.h])
  58 AC_CHECK_HEADERS([netdb.h])
  59 AC_CHECK_HEADERS([poll.h])
  60 AC_CHECK_HEADERS([pthread.h])
  61 AC_CHECK_HEADERS([strings.h])
  62 AC_CHECK_HEADERS([sys/ioctl.h])
  63 AC_CHECK_HEADERS([sys/param.h])
  64 AC_CHECK_HEADERS([sys/select.h])
  65 AC_CHECK_HEADERS([sys/stat.h])
  66 AC_CHECK_HEADERS([sys/sysctl.h])
  67 AC_CHECK_HEADERS([sys/time.h])
  68 AC_CHECK_HEADERS([sys/types.h])
  69 AC_CHECK_HEADERS([unistd.h])
  70 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  71 #include <stdio.h>
  72 #ifdef STDC_HEADERS
  73 # include <stdlib.h>
  74 # include <stddef.h>
  75 #else
  76 # ifdef HAVE_STDLIB_H
  77 #  include <stdlib.h>
  78 # endif
  79 #endif
  80 #ifdef HAVE_SYS_SOCKET_H
  81 # include <sys/socket.h>
  82 #endif
  83 ])
  84
  85 AC_HEADER_ASSERT
  86 AC_HEADER_STDBOOL
  87
  88 AC_C_BIGENDIAN
  89
  90 AC_CHECK_FUNCS([strndup])
  91 AC_CHECK_FUNCS([strnlen])
  92 AC_CHECK_FUNCS([gettimeofday])
  93 AC_CHECK_FUNCS([usleep])
  94 AC_CHECK_FUNCS([vasprintf])
  95 AC_CHECK_FUNCS([realpath])
  96
  97 # guess-rev.sh only exists in the repository, not in the released archives
  98 AC_MSG_CHECKING([whether to build a release])
  99 AS_IF([test -x "$srcdir/guess-rev.sh"], [
 100   build_release=no
 101 ], [
 102   build_release=yes
 103 ])
 104 AC_MSG_RESULT([$build_release])
 105
 106 # Adapter drivers
 107 # 1st column -- configure option
 108 # 2nd column -- description
 109 # 3rd column -- symbol used for both config.h and automake
 110 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 111 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 112 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 113 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 114 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 115
 116 m4_define([USB1_ADAPTERS],
 117         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 118         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 119         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 120         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 121         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 122         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 123         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 124         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 125         [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
 126         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 127         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 128         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]],
 129         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 130         [[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 131         [[aice], [Andes JTAG Programmer], [AICE]]])
 132
 133 m4_define([HIDAPI_ADAPTERS],
 134         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
 135         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 136
 137 m4_define([HIDAPI_USB1_ADAPTERS],
 138         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 139
 140 m4_define([LIBFTDI_ADAPTERS],
 141         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 142         [[presto], [ASIX Presto Adapter], [PRESTO]]])
 143
 144 m4_define([LIBFTDI_USB1_ADAPTERS],
 145         [[[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 146
 147 m4_define([LIBGPIOD_ADAPTERS],
 148         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 149
 150 m4_define([LIBJAYLINK_ADAPTERS],
 151         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 152
 153 m4_define([PCIE_ADAPTERS],
 154         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 155
 156 m4_define([OPTIONAL_LIBRARIES],
 157         [[[capstone], [Use Capstone disassembly framework], []]])
 158
 159 AC_ARG_ENABLE([doxygen-html],
 160   AS_HELP_STRING([--disable-doxygen-html],
 161     [Disable building Doxygen manual as HTML.]),
 162   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 163 AC_SUBST([doxygen_as_html])
 164 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 165 AC_MSG_RESULT([$doxygen_as_html])
 166
 167 AC_ARG_ENABLE([doxygen-pdf],
 168   AS_HELP_STRING([--enable-doxygen-pdf],
 169     [Enable building Doxygen manual as PDF.]),
 170   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 171 AC_SUBST([doxygen_as_pdf])
 172 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 173 AC_MSG_RESULT([$doxygen_as_pdf])
 174
 175 AC_ARG_ENABLE([gccwarnings],
 176   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 177   [gcc_warnings=$enableval], [gcc_warnings=yes])
 178
 179 AC_ARG_ENABLE([wextra],
 180   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 181   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 182
 183 AC_ARG_ENABLE([werror],
 184   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 185   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 186
 187 # set default verbose options, overridden by following options
 188 debug_usb_io=no
 189 debug_usb_comms=no
 190
 191 AC_ARG_ENABLE([verbose],
 192   AS_HELP_STRING([--enable-verbose],
 193       [Enable verbose JTAG I/O messages (for debugging).]),
 194   [
 195   debug_usb_io=$enableval
 196   debug_usb_comms=$enableval
 197   ], [])
 198
 199 AC_ARG_ENABLE([verbose_usb_io],
 200   AS_HELP_STRING([--enable-verbose-usb-io],
 201       [Enable verbose USB I/O messages (for debugging)]),
 202   [debug_usb_io=$enableval], [])
 203
 204 AC_ARG_ENABLE([verbose_usb_comms],
 205   AS_HELP_STRING([--enable-verbose-usb-comms],
 206       [Enable verbose USB communication messages (for debugging)]),
 207   [debug_usb_comms=$enableval], [])
 208
 209 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 210 AC_MSG_RESULT([$debug_usb_io])
 211 AS_IF([test "x$debug_usb_io" = "xyes"], [
 212   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 213 ])
 214
 215 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 216 AC_MSG_RESULT([$debug_usb_comms])
 217 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 218   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 219 ])
 220
 221 debug_malloc=no
 222 AC_ARG_ENABLE([malloc_logging],
 223   AS_HELP_STRING([--enable-malloc-logging],
 224       [Include free space in logging messages (requires malloc.h).]),
 225   [debug_malloc=$enableval], [])
 226
 227 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 228 AC_MSG_RESULT([$debug_malloc])
 229 AS_IF([test "x$debug_malloc" = "xyes"], [
 230   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 231 ])
 232
 233 AC_ARG_ENABLE([dummy],
 234   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 235   [build_dummy=$enableval], [build_dummy=no])
 236
 237 AC_ARG_ENABLE([rshim],
 238   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 239   [build_rshim=$enableval], [build_rshim=no])
 240
 241 m4_define([AC_ARG_ADAPTERS], [
 242   m4_foreach([adapter], [$1],
 243         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 244                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 245                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 246                 [], [ADAPTER_VAR([adapter])=$2])
 247   ])
 248 ])
 249
 250 AC_ARG_ADAPTERS([
 251   USB1_ADAPTERS,
 252   HIDAPI_ADAPTERS,
 253   HIDAPI_USB1_ADAPTERS,
 254   LIBFTDI_ADAPTERS,
 255   LIBFTDI_USB1_ADAPTERS
 256   LIBGPIOD_ADAPTERS,
 257   LIBJAYLINK_ADAPTERS
 258   ],[auto])
 259
 260 AC_ARG_ENABLE([parport],
 261   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 262   [build_parport=$enableval], [build_parport=no])
 263
 264 AC_ARG_ENABLE([parport_ppdev],
 265   AS_HELP_STRING([--disable-parport-ppdev],
 266       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 267     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 268
 269 AC_ARG_ENABLE([parport_giveio],
 270     AS_HELP_STRING([--enable-parport-giveio],
 271       [Enable use of giveio for parport (for CygWin only)]),
 272     [parport_use_giveio=$enableval], [parport_use_giveio=])
 273
 274 AC_ARG_ENABLE([jtag_vpi],
 275   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 276   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 277
 278 AC_ARG_ENABLE([jtag_dpi],
 279   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 280   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 281
 282 AC_ARG_ENABLE([amtjtagaccel],
 283   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 284   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 285
 286 AS_CASE(["${host_cpu}"],
 287   [arm*|aarch64], [
 288     AC_ARG_ENABLE([bcm2835gpio],
 289       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 290       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 291     AC_ARG_ENABLE([imx_gpio],
 292       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 293       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 294   ],
 295   [
 296     build_bcm2835gpio=no
 297     build_imx_gpio=no
 298 ])
 299
 300 AS_CASE(["${host_cpu}"],
 301   [arm*], [
 302     AC_ARG_ENABLE([ep93xx],
 303       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 304       [build_ep93xx=$enableval], [build_ep93xx=no])
 305
 306     AC_ARG_ENABLE([at91rm9200],
 307       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 308       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 309   ],
 310   [
 311     build_ep93xx=no
 312     build_at91rm9200=no
 313 ])
 314
 315 AC_ARG_ENABLE([gw16012],
 316   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 317   [build_gw16012=$enableval], [build_gw16012=no])
 318
 319 AC_ARG_ENABLE([buspirate],
 320   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 321   [build_buspirate=$enableval], [build_buspirate=no])
 322
 323 AC_ARG_ENABLE([sysfsgpio],
 324   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 325   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 326
 327 AC_ARG_ENABLE([xlnx_pcie_xvc],
 328   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 329   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 330
 331 AS_CASE([$host_os],
 332   [linux*], [],
 333   [
 334     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 335       AC_MSG_ERROR([sysfsgpio is only available on linux])
 336     ])
 337
 338     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 339       AC_MSG_ERROR([linuxgpiod is only available on linux])
 340     ])
 341
 342     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 343       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 344     ])
 345
 346     AS_CASE([$host_os], [freebsd*], [],
 347     [
 348       AS_IF([test "x$build_rshim" = "xyes"], [
 349         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 350       ])
 351     ])
 352 ])
 353
 354 AC_ARG_ENABLE([internal-jimtcl],
 355   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 356   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 357
 358 AC_ARG_ENABLE([internal-libjaylink],
 359   AS_HELP_STRING([--disable-internal-libjaylink],
 360   [Disable building internal libjaylink]),
 361   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 362
 363 AC_ARG_ENABLE([remote-bitbang],
 364   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 365   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 366
 367 AS_CASE(["${host_cpu}"],
 368   [i?86|x86*], [],
 369   [
 370     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 371       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 372     ])
 373     parport_use_ppdev=yes
 374 ])
 375
 376 AS_CASE([$host],
 377   [*-cygwin*], [
 378     is_win32=yes
 379     parport_use_ppdev=no
 380
 381     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 382       [is_mingw=yes],[is_mingw=no])
 383     AS_IF([test "x$is_mingw" = "xyes"], [
 384       AS_IF([test "x$parport_use_giveio" = "xno"], [
 385         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 386       ])
 387       parport_use_giveio=yes
 388       is_cygwin=no
 389     ], [
 390       is_cygwin=yes
 391       # sys/io.h needed under cygwin for parport access
 392       AS_IF([test "x$build_parport" = "xyes"], [
 393         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 394       ])
 395     ])
 396   ],
 397   [*-mingw* | *-msys*], [
 398     is_mingw=yes
 399     is_win32=yes
 400     parport_use_ppdev=no
 401
 402     AS_IF([test "x$parport_use_giveio" = "xno"], [
 403       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 404     ])
 405     parport_use_giveio=yes
 406
 407     AS_IF([test "x$build_buspirate" = "xyes"], [
 408       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 409     ])
 410
 411     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 412   ],
 413   [*darwin*], [
 414     is_darwin=yes
 415
 416     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 417       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 418     ])
 419     parport_use_giveio=no
 420   ],
 421   [
 422     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 423       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 424     ])
 425     parport_use_giveio=no
 426 ])
 427
 428 AS_IF([test "x$is_cygwin" = "xyes"], [
 429     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 430 ], [
 431     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 432 ])
 433
 434 AS_IF([test "x$is_mingw" = "xyes"], [
 435     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 436 ], [
 437     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 438 ])
 439
 440 AS_IF([test "x$is_win32" = "xyes"], [
 441     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 442 ], [
 443     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 444 ])
 445
 446 AS_IF([test "x$is_darwin" = "xyes"], [
 447     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 448 ], [
 449     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 450 ])
 451
 452 AS_IF([test "x$build_parport" = "xyes"], [
 453   build_bitbang=yes
 454   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 455 ], [
 456   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 457 ])
 458
 459 AS_IF([test "x$build_rshim" = "xyes"], [
 460   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 461 ], [
 462   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 463 ])
 464
 465 AS_IF([test "x$build_dummy" = "xyes"], [
 466   build_bitbang=yes
 467   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 468 ], [
 469   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 470 ])
 471
 472 AS_IF([test "x$build_ep93xx" = "xyes"], [
 473   build_bitbang=yes
 474   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 475 ], [
 476   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 477 ])
 478
 479 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 480   build_bitbang=yes
 481   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 482 ], [
 483   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 484 ])
 485
 486 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 487   build_bitbang=yes
 488   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 489 ], [
 490   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 491 ])
 492
 493 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 494   build_bitbang=yes
 495   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 496 ], [
 497   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 498 ])
 499
 500 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 501   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 502 ], [
 503   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 504 ])
 505
 506 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 507   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 508 ], [
 509   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 510 ])
 511
 512 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 513   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 514 ], [
 515   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 516 ])
 517
 518 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 519   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 520 ], [
 521   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 522 ])
 523
 524
 525 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 526   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 527 ], [
 528   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 529 ])
 530
 531 AS_IF([test "x$build_gw16012" = "xyes"], [
 532   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 533 ], [
 534   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 535 ])
 536
 537 AS_IF([test "x$build_buspirate" = "xyes"], [
 538   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 539 ], [
 540   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 541 ])
 542
 543 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 544   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 545     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 546   ], [
 547     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 548   ])
 549 ])
 550
 551 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 552   build_bitbang=yes
 553   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 554 ], [
 555   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 556 ])
 557
 558 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 559   build_bitbang=yes
 560   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 561 ], [
 562   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 563 ])
 564
 565 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 566   build_xlnx_pcie_xvc=yes
 567   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 568 ], [
 569   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 570 ])
 571
 572 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 573         use_libusb1=yes
 574         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 575         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 576                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 577                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 578         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 579         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 580         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 581                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 582   ], [
 583         use_libusb1=no
 584         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 585 ])
 586
 587 AC_ARG_WITH([capstone],
 588                 AS_HELP_STRING([--with-capstone], [Use Capstone disassembly library (default=auto)])
 589         , [
 590                 enable_capstone=$withval
 591         ], [
 592                 enable_capstone=auto
 593 ])
 594
 595 AS_IF([test "x$enable_capstone" != xno], [
 596         PKG_CHECK_MODULES([CAPSTONE], [capstone], [
 597                 AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have Capstone disassembly framework.])
 598         ], [
 599                 AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have Capstone disassembly framework.])
 600                 if test "x$enable_capstone" != xauto; then
 601                         AC_MSG_ERROR([--with-capstone was given, but test for Capstone failed])
 602                 fi
 603                 enable_capstone=no
 604         ])
 605 ])
 606
 607 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 608         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 609                 use_hidapi=yes
 610                 break
 611         ],[
 612                 use_hidapi=no
 613         ])
 614 done
 615
 616 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 617         use_libftdi=yes
 618         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 619                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 620   ], [
 621         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 622 ])
 623
 624 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 625
 626 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 627         [use_libjaylink=yes], [use_libjaylink=no])
 628
 629 m4_define([PROCESS_ADAPTERS], [
 630   m4_foreach([adapter], [$1], [
 631         AS_IF([test $2], [
 632                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 633                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 634                 ], [
 635                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 636                 ])
 637         ], [
 638                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 639                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 640                 ])
 641                 ADAPTER_VAR([adapter])=no
 642         ])
 643         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 644   ])
 645 ])
 646
 647 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 648 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 649 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 650 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 651 PROCESS_ADAPTERS([LIBFTDI_USB1_ADAPTERS], ["x$use_libftdi" = "xyes" -a "x$use_libusb1" = "xyes"], [libftdi and libusb-1.x])
 652 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 653 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 654
 655 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 656   build_bitbang=yes
 657 ])
 658
 659 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 660         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 661         AM_CONDITIONAL([HLADAPTER], [true])
 662 ], [
 663         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 664         AM_CONDITIONAL([HLADAPTER], [false])
 665 ])
 666 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 667 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 668 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 669
 670 AS_IF([test "x$enable_jlink" != "xno"], [
 671   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 672     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 673       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 674                 [--enable-subproject-build])
 675     ], [
 676       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 677     ])
 678   ])
 679 ])
 680
 681 # Presto needs the bitq module
 682 AS_IF([test "x$enable_presto" != "xno"], [
 683   build_bitq=yes
 684 ])
 685
 686 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 687 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 688 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 689 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 690 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 691 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 692 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 693 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 694 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 695 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 696 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 697 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 698 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 699 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 700 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 701 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 702 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 703 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 704 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 705 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 706 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 707 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 708 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 709 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 710 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 711 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 712 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 713 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 714 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 715 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$enable_capstone" != "xno"])
 716
 717 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 718 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 719
 720 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 721 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 722 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 723 #define _GNU_SOURCE
 724 #include <unistd.h>
 725 #include <stdlib.h>
 726   ]], [[char **ep = environ;]]
 727   )], [
 728     AC_MSG_RESULT([yes])
 729     has_environ=yes
 730   ], [
 731     AC_MSG_RESULT([no])
 732
 733     # Possibility #2: can environ be found in an available library?
 734     AC_MSG_CHECKING([for extern environ])
 735     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 736     extern char **environ;
 737     ]], [[char **ep = environ;]]
 738       )], [
 739         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 740         has_environ=yes
 741       ], [
 742         has_environ=no
 743       ])
 744     AC_MSG_RESULT([${has_environ}])
 745   ])
 746
 747 AS_IF([test "x${has_environ}" != "xyes" ], [
 748   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 749 ])
 750
 751 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 752
 753 # set default gcc warnings
 754 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 755 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 756   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 757   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 758   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 759   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 760   GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
 761 ])
 762 AS_IF([test "x${gcc_werror}" = "xyes"], [
 763   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 764 ])
 765
 766 # override default gcc cflags
 767 AS_IF([test "x$gcc_warnings" = "xyes"], [
 768   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 769 ])
 770
 771 AC_SUBST(EXTRA_DIST_NEWS, ["$(echo $srcdir/NEWS-*)"])
 772
 773 AC_CONFIG_FILES([
 774   Makefile
 775 ])
 776 AC_OUTPUT
 777
 778 echo
 779 echo
 780 echo OpenOCD configuration summary
 781 echo --------------------------------------------------
 782 m4_foreach([adapter], [USB1_ADAPTERS,
 783         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 784         LIBFTDI_USB1_ADAPTERS,
 785         LIBGPIOD_ADAPTERS,
 786         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS,
 787         OPTIONAL_LIBRARIES],
 788         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 789         AS_CASE([$ADAPTER_VAR([adapter])],
 790                 [auto], [
 791                         echo "$s"yes '(auto)'
 792                 ],
 793                 [yes], [
 794                         echo "$s"yes
 795                 ],
 796                 [no], [
 797                         echo "$s"no
 798         ])
 799 ])
 800 echo