configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.11.0-rc1+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5 AC_CONFIG_AUX_DIR([.])
   6
   7 m4_include([config_subdir.m4])dnl
   8
   9 # check for makeinfo before calling AM_INIT_AUTOMAKE
  10 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  11 AS_IF([test "x$MAKEINFO" = "x"], [
  12   MAKEINFO='echo makeinfo missing; true'
  13   AC_MSG_WARN([Info documentation will not be built.])
  14 ])
  15 AC_SUBST([MAKEINFO])
  16
  17 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20 AH_BOTTOM([
  21 #include <helper/system.h>
  22 #include <helper/types.h>
  23 #include <helper/replacements.h>
  24 ])
  25
  26 AC_LANG([C])
  27 AC_PROG_CC
  28 AC_PROG_CC_C99
  29 AM_PROG_CC_C_O
  30 AC_PROG_RANLIB
  31 PKG_PROG_PKG_CONFIG([0.23])
  32
  33 dnl disable checks for C++, Fortran and GNU Java Compiler
  34 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  36 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  37 AC_DISABLE_SHARED
  38 LT_INIT
  39 AC_SUBST([LIBTOOL_DEPS])
  40
  41 dnl configure checks required for Jim files (these are obsolete w/ C99)
  42 AC_C_CONST
  43 AC_TYPE_LONG_LONG_INT
  44
  45 AC_SEARCH_LIBS([ioperm], [ioperm])
  46 AC_SEARCH_LIBS([dlopen], [dl])
  47 AC_SEARCH_LIBS([openpty], [util])
  48
  49 AC_CHECK_HEADERS([sys/socket.h])
  50 AC_CHECK_HEADERS([elf.h])
  51 AC_CHECK_HEADERS([dirent.h])
  52 AC_CHECK_HEADERS([fcntl.h])
  53 AC_CHECK_HEADERS([malloc.h])
  54 AC_CHECK_HEADERS([netdb.h])
  55 AC_CHECK_HEADERS([poll.h])
  56 AC_CHECK_HEADERS([pthread.h])
  57 AC_CHECK_HEADERS([strings.h])
  58 AC_CHECK_HEADERS([sys/ioctl.h])
  59 AC_CHECK_HEADERS([sys/param.h])
  60 AC_CHECK_HEADERS([sys/select.h])
  61 AC_CHECK_HEADERS([sys/stat.h])
  62 AC_CHECK_HEADERS([sys/sysctl.h])
  63 AC_CHECK_HEADERS([sys/time.h])
  64 AC_CHECK_HEADERS([sys/types.h])
  65 AC_CHECK_HEADERS([unistd.h])
  66 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  67 #include <stdio.h>
  68 #ifdef STDC_HEADERS
  69 # include <stdlib.h>
  70 # include <stddef.h>
  71 #else
  72 # ifdef HAVE_STDLIB_H
  73 #  include <stdlib.h>
  74 # endif
  75 #endif
  76 #ifdef HAVE_SYS_SOCKET_H
  77 # include <sys/socket.h>
  78 #endif
  79 ])
  80
  81 AC_HEADER_ASSERT
  82 AC_HEADER_STDBOOL
  83 AC_HEADER_TIME
  84
  85 AC_C_BIGENDIAN
  86
  87 AC_CHECK_FUNCS([strndup])
  88 AC_CHECK_FUNCS([strnlen])
  89 AC_CHECK_FUNCS([gettimeofday])
  90 AC_CHECK_FUNCS([usleep])
  91 AC_CHECK_FUNCS([vasprintf])
  92 AC_CHECK_FUNCS([realpath])
  93
  94 # guess-rev.sh only exists in the repository, not in the released archives
  95 AC_MSG_CHECKING([whether to build a release])
  96 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  97   build_release=no
  98 ], [
  99   build_release=yes
 100 ])
 101 AC_MSG_RESULT([$build_release])
 102
 103 # Adapter drivers
 104 # 1st column -- configure option
 105 # 2nd column -- description
 106 # 3rd column -- symbol used for both config.h and automake
 107 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 108 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 109 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 110 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 111 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 112
 113 m4_define([USB1_ADAPTERS],
 114         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 115         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 116         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 117         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 118         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 119         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 120         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 121         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 122         [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
 123         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 124         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 125         [[aice], [Andes JTAG Programmer], [AICE]]])
 126
 127 m4_define([USB0_ADAPTERS],
 128         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 129         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 130         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 131
 132 m4_define([HIDAPI_ADAPTERS],
 133         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
 134         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 135
 136 m4_define([HIDAPI_USB1_ADAPTERS],
 137         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 138
 139 m4_define([LIBFTDI_ADAPTERS],
 140         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 141         [[presto], [ASIX Presto Adapter], [PRESTO]],
 142         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 143
 144 m4_define([LIBGPIOD_ADAPTERS],
 145         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 146
 147 m4_define([LIBJAYLINK_ADAPTERS],
 148         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 149
 150 m4_define([PCIE_ADAPTERS],
 151         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 152
 153 m4_define([OPTIONAL_LIBRARIES],
 154         [[[capstone], [Use Capstone disassembly framework], []]])
 155
 156 AC_ARG_ENABLE([doxygen-html],
 157   AS_HELP_STRING([--disable-doxygen-html],
 158     [Disable building Doxygen manual as HTML.]),
 159   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 160 AC_SUBST([doxygen_as_html])
 161 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 162 AC_MSG_RESULT([$doxygen_as_html])
 163
 164 AC_ARG_ENABLE([doxygen-pdf],
 165   AS_HELP_STRING([--enable-doxygen-pdf],
 166     [Enable building Doxygen manual as PDF.]),
 167   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 168 AC_SUBST([doxygen_as_pdf])
 169 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 170 AC_MSG_RESULT([$doxygen_as_pdf])
 171
 172 AC_ARG_ENABLE([gccwarnings],
 173   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 174   [gcc_warnings=$enableval], [gcc_warnings=yes])
 175
 176 AC_ARG_ENABLE([wextra],
 177   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 178   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 179
 180 AC_ARG_ENABLE([werror],
 181   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 182   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 183
 184 # set default verbose options, overridden by following options
 185 debug_usb_io=no
 186 debug_usb_comms=no
 187
 188 AC_ARG_ENABLE([verbose],
 189   AS_HELP_STRING([--enable-verbose],
 190       [Enable verbose JTAG I/O messages (for debugging).]),
 191   [
 192   debug_usb_io=$enableval
 193   debug_usb_comms=$enableval
 194   ], [])
 195
 196 AC_ARG_ENABLE([verbose_usb_io],
 197   AS_HELP_STRING([--enable-verbose-usb-io],
 198       [Enable verbose USB I/O messages (for debugging)]),
 199   [debug_usb_io=$enableval], [])
 200
 201 AC_ARG_ENABLE([verbose_usb_comms],
 202   AS_HELP_STRING([--enable-verbose-usb-comms],
 203       [Enable verbose USB communication messages (for debugging)]),
 204   [debug_usb_comms=$enableval], [])
 205
 206 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 207 AC_MSG_RESULT([$debug_usb_io])
 208 AS_IF([test "x$debug_usb_io" = "xyes"], [
 209   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 210 ])
 211
 212 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 213 AC_MSG_RESULT([$debug_usb_comms])
 214 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 215   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 216 ])
 217
 218 debug_malloc=no
 219 AC_ARG_ENABLE([malloc_logging],
 220   AS_HELP_STRING([--enable-malloc-logging],
 221       [Include free space in logging messages (requires malloc.h).]),
 222   [debug_malloc=$enableval], [])
 223
 224 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 225 AC_MSG_RESULT([$debug_malloc])
 226 AS_IF([test "x$debug_malloc" = "xyes"], [
 227   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 228 ])
 229
 230 AC_ARG_ENABLE([dummy],
 231   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 232   [build_dummy=$enableval], [build_dummy=no])
 233
 234 AC_ARG_ENABLE([rshim],
 235   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 236   [build_rshim=$enableval], [build_rshim=no])
 237
 238 m4_define([AC_ARG_ADAPTERS], [
 239   m4_foreach([adapter], [$1],
 240         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 241                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 242                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 243                 [], [ADAPTER_VAR([adapter])=$2])
 244   ])
 245 ])
 246
 247 AC_ARG_ADAPTERS([
 248   USB1_ADAPTERS,
 249   USB0_ADAPTERS,
 250   HIDAPI_ADAPTERS,
 251   HIDAPI_USB1_ADAPTERS,
 252   LIBFTDI_ADAPTERS,
 253   LIBGPIOD_ADAPTERS,
 254   LIBJAYLINK_ADAPTERS
 255   ],[auto])
 256
 257 AC_ARG_ENABLE([parport],
 258   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 259   [build_parport=$enableval], [build_parport=no])
 260
 261 AC_ARG_ENABLE([parport_ppdev],
 262   AS_HELP_STRING([--disable-parport-ppdev],
 263       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 264     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 265
 266 AC_ARG_ENABLE([parport_giveio],
 267     AS_HELP_STRING([--enable-parport-giveio],
 268       [Enable use of giveio for parport (for CygWin only)]),
 269     [parport_use_giveio=$enableval], [parport_use_giveio=])
 270
 271 AC_ARG_ENABLE([jtag_vpi],
 272   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 273   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 274
 275 AC_ARG_ENABLE([jtag_dpi],
 276   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 277   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 278
 279 AC_ARG_ENABLE([amtjtagaccel],
 280   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 281   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 282
 283 AC_ARG_ENABLE([zy1000_master],
 284   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 285   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 286
 287 AC_ARG_ENABLE([zy1000],
 288   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 289   [build_zy1000=$enableval], [build_zy1000=no])
 290
 291 AC_ARG_ENABLE([ioutil],
 292   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 293   [build_ioutil=$enableval], [build_ioutil=no])
 294
 295 AS_CASE(["${host_cpu}"],
 296   [arm*|aarch64], [
 297     AC_ARG_ENABLE([bcm2835gpio],
 298       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 299       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 300     AC_ARG_ENABLE([imx_gpio],
 301       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 302       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 303   ],
 304   [
 305     build_bcm2835gpio=no
 306     build_imx_gpio=no
 307 ])
 308
 309 AS_CASE(["${host_cpu}"],
 310   [arm*], [
 311     AC_ARG_ENABLE([ep93xx],
 312       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 313       [build_ep93xx=$enableval], [build_ep93xx=no])
 314
 315     AC_ARG_ENABLE([at91rm9200],
 316       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 317       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 318   ],
 319   [
 320     build_ep93xx=no
 321     build_at91rm9200=no
 322 ])
 323
 324 AC_ARG_ENABLE([gw16012],
 325   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 326   [build_gw16012=$enableval], [build_gw16012=no])
 327
 328 AC_ARG_ENABLE([oocd_trace],
 329   AS_HELP_STRING([--enable-oocd_trace],
 330   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 331   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 332
 333 AC_ARG_ENABLE([buspirate],
 334   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 335   [build_buspirate=$enableval], [build_buspirate=no])
 336
 337 AC_ARG_ENABLE([sysfsgpio],
 338   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 339   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 340
 341 AC_ARG_ENABLE([xlnx_pcie_xvc],
 342   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 343   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 344
 345 AS_CASE([$host_os],
 346   [linux*], [],
 347   [
 348     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 349       AC_MSG_ERROR([sysfsgpio is only available on linux])
 350     ])
 351
 352     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 353       AC_MSG_ERROR([linuxgpiod is only available on linux])
 354     ])
 355
 356     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 357       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 358     ])
 359
 360     AS_CASE([$host_os], [freebsd*], [],
 361     [
 362       AS_IF([test "x$build_rshim" = "xyes"], [
 363         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 364       ])
 365     ])
 366 ])
 367
 368 AC_ARG_ENABLE([minidriver_dummy],
 369   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 370   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 371
 372 AC_ARG_ENABLE([internal-jimtcl],
 373   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 374   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 375
 376 AC_ARG_ENABLE([internal-libjaylink],
 377   AS_HELP_STRING([--disable-internal-libjaylink],
 378   [Disable building internal libjaylink]),
 379   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 380
 381 build_minidriver=no
 382 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 383 AS_IF([test "x$build_zy1000" = "xyes"], [
 384   AS_IF([test "x$build_minidriver" = "xyes"], [
 385     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 386   ])
 387   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 388       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 389   build_minidriver=yes
 390 ])
 391 AC_MSG_RESULT([$build_zy1000])
 392
 393 AC_ARG_ENABLE([remote-bitbang],
 394   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 395   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 396
 397 AC_MSG_CHECKING([whether to enable dummy minidriver])
 398 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 399   AS_IF([test "x$build_minidriver" = "xyes"], [
 400     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 401   ])
 402   build_minidriver=yes
 403   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 404   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 405       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 406 ])
 407 AC_MSG_RESULT([$build_minidriver_dummy])
 408
 409 AC_MSG_CHECKING([whether standard drivers can be built])
 410 AS_IF([test "x$build_minidriver" = "xyes"], [
 411   AC_MSG_RESULT([no])
 412   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 413   sleep 2
 414 ], [
 415   AC_MSG_RESULT([yes])
 416 ])
 417
 418 AS_CASE(["${host_cpu}"],
 419   [i?86|x86*], [],
 420   [
 421     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 422       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 423     ])
 424     parport_use_ppdev=yes
 425 ])
 426
 427 AS_CASE([$host],
 428   [*-cygwin*], [
 429     is_win32=yes
 430     parport_use_ppdev=no
 431
 432     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 433       [is_mingw=yes],[is_mingw=no])
 434     AS_IF([test "x$is_mingw" = "xyes"], [
 435       AS_IF([test "x$parport_use_giveio" = "xno"], [
 436         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 437       ])
 438       parport_use_giveio=yes
 439       is_cygwin=no
 440     ], [
 441       is_cygwin=yes
 442       # sys/io.h needed under cygwin for parport access
 443       AS_IF([test "x$build_parport" = "xyes"], [
 444         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 445       ])
 446     ])
 447   ],
 448   [*-mingw* | *-msys*], [
 449     is_mingw=yes
 450     is_win32=yes
 451     parport_use_ppdev=no
 452
 453     AS_IF([test "x$parport_use_giveio" = "xno"], [
 454       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 455     ])
 456     parport_use_giveio=yes
 457
 458     AS_IF([test "x$build_buspirate" = "xyes"], [
 459       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 460     ])
 461
 462     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 463   ],
 464   [*darwin*], [
 465     is_darwin=yes
 466
 467     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 468       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 469     ])
 470     parport_use_giveio=no
 471   ],
 472   [
 473     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 474       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 475     ])
 476     parport_use_giveio=no
 477 ])
 478
 479 AS_IF([test "x$is_cygwin" = "xyes"], [
 480     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 481 ], [
 482     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 483 ])
 484
 485 AS_IF([test "x$is_mingw" = "xyes"], [
 486     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 487 ], [
 488     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 489 ])
 490
 491 AS_IF([test "x$is_win32" = "xyes"], [
 492     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 493 ], [
 494     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 495 ])
 496
 497 AS_IF([test "x$is_darwin" = "xyes"], [
 498     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 499 ], [
 500     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 501 ])
 502
 503 AS_IF([test "x$build_parport" = "xyes"], [
 504   build_bitbang=yes
 505   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 506 ], [
 507   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 508 ])
 509
 510 AS_IF([test "x$build_rshim" = "xyes"], [
 511   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 512 ], [
 513   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 514 ])
 515
 516 AS_IF([test "x$build_dummy" = "xyes"], [
 517   build_bitbang=yes
 518   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 519 ], [
 520   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 521 ])
 522
 523 AS_IF([test "x$build_ep93xx" = "xyes"], [
 524   build_bitbang=yes
 525   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 526 ], [
 527   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 528 ])
 529
 530 AS_IF([test "x$build_zy1000" = "xyes"], [
 531   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 532 ], [
 533   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 534 ])
 535
 536 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 537   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 538 ], [
 539   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 540 ])
 541
 542 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 543   build_bitbang=yes
 544   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 545 ], [
 546   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 547 ])
 548
 549 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 550   build_bitbang=yes
 551   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 552 ], [
 553   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 554 ])
 555
 556 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 557   build_bitbang=yes
 558   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 559 ], [
 560   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 561 ])
 562
 563 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 564   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 565 ], [
 566   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 567 ])
 568
 569 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 570   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 571 ], [
 572   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 573 ])
 574
 575 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 576   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 577 ], [
 578   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 579 ])
 580
 581 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 582   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 583 ], [
 584   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 585 ])
 586
 587
 588 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 589   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 590 ], [
 591   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 592 ])
 593
 594 AS_IF([test "x$build_gw16012" = "xyes"], [
 595   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 596 ], [
 597   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 598 ])
 599
 600 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 601   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 602 ], [
 603   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 604 ])
 605
 606 AS_IF([test "x$build_buspirate" = "xyes"], [
 607   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 608 ], [
 609   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 610 ])
 611
 612 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 613   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 614     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 615   ], [
 616     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 617   ])
 618 ])
 619
 620 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 621   build_bitbang=yes
 622   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 623 ], [
 624   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 625 ])
 626
 627 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 628   build_bitbang=yes
 629   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 630 ], [
 631   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 632 ])
 633
 634 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 635   build_xlnx_pcie_xvc=yes
 636   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 637 ], [
 638   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 639 ])
 640
 641 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 642         use_libusb1=yes
 643         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 644         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 645                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 646                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 647         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 648         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 649         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 650                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 651   ], [
 652         use_libusb1=no
 653         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 654 ])
 655
 656 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 657
 658 AC_ARG_WITH([capstone],
 659                 AS_HELP_STRING([--with-capstone], [Use Capstone disassembly library (default=auto)])
 660         , [
 661                 enable_capstone=$withval
 662         ], [
 663                 enable_capstone=auto
 664 ])
 665
 666 AS_IF([test "x$enable_capstone" != xno], [
 667         PKG_CHECK_MODULES([CAPSTONE], [capstone], [
 668                 AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have Capstone disassembly framework.])
 669         ], [
 670                 AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have Capstone disassembly framework.])
 671                 if test "x$enable_capstone" != xauto; then
 672                         AC_MSG_ERROR([--with-capstone was given, but test for Capstone failed])
 673                 fi
 674                 enable_capstone=no
 675         ])
 676 ])
 677
 678 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 679         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 680                 use_hidapi=yes
 681                 break
 682         ],[
 683                 use_hidapi=no
 684         ])
 685 done
 686
 687 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 688         use_libftdi=yes
 689         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 690                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 691   ], [
 692         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 693 ])
 694
 695 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 696
 697 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 698         [use_libjaylink=yes], [use_libjaylink=no])
 699
 700 m4_define([PROCESS_ADAPTERS], [
 701   m4_foreach([adapter], [$1], [
 702         AS_IF([test "x$build_zy1000" = "xyes"], [
 703                 ADAPTER_VAR([adapter])=no
 704         ])
 705         AS_IF([test $2], [
 706                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 707                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 708                 ], [
 709                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 710                 ])
 711         ], [
 712                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 713                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 714                 ])
 715                 ADAPTER_VAR([adapter])=no
 716         ])
 717         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 718   ])
 719 ])
 720
 721 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 722 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 723 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 724 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 725 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 726 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 727 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 728
 729 AS_IF([test "x$build_openjtag" = "xyes"], [
 730   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 731     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 732     build_openjtag=no
 733   ])
 734 ])
 735
 736 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 737   build_bitbang=yes
 738 ])
 739
 740 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 741         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 742         AM_CONDITIONAL([HLADAPTER], [true])
 743 ], [
 744         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 745         AM_CONDITIONAL([HLADAPTER], [false])
 746 ])
 747 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 748 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 749 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 750
 751 AS_IF([test "x$enable_jlink" != "xno"], [
 752   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 753     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 754       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 755                 [--enable-subproject-build])
 756     ], [
 757       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 758     ])
 759   ])
 760 ])
 761
 762 # Presto needs the bitq module
 763 AS_IF([test "x$enable_presto" != "xno"], [
 764   build_bitq=yes
 765 ])
 766
 767 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 768 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 769 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 770 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 771 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 772 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 773 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 774 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 775 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 776 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 777 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 778 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 779 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 780 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 781 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 782 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 783 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 784 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 785 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 786 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 787 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 788 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 789 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 790 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 791 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 792 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 793 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 794 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 795 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 796 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 797 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 798 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 799 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 800 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 801 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$enable_capstone" != "xno"])
 802
 803 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 804 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 805
 806 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 807 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 808
 809 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 810 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 811 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 812 #define _GNU_SOURCE
 813 #include <unistd.h>
 814 #include <stdlib.h>
 815   ]], [[char **ep = environ;]]
 816   )], [
 817     AC_MSG_RESULT([yes])
 818     has_environ=yes
 819   ], [
 820     AC_MSG_RESULT([no])
 821
 822     # Possibility #2: can environ be found in an available library?
 823     AC_MSG_CHECKING([for extern environ])
 824     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 825     extern char **environ;
 826     ]], [[char **ep = environ;]]
 827       )], [
 828         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 829         has_environ=yes
 830       ], [
 831         has_environ=no
 832       ])
 833     AC_MSG_RESULT([${has_environ}])
 834   ])
 835
 836 AS_IF([test "x${has_environ}" != "xyes" ], [
 837   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 838 ])
 839
 840 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 841
 842 # set default gcc warnings
 843 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 844 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 845   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 846   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 847   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 848   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 849   GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
 850 ])
 851 AS_IF([test "x${gcc_werror}" = "xyes"], [
 852   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 853 ])
 854
 855 # override default gcc cflags
 856 AS_IF([test "x$gcc_warnings" = "xyes"], [
 857   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 858 ])
 859
 860 AC_CONFIG_FILES([
 861   Makefile
 862 ])
 863 AC_OUTPUT
 864
 865 echo
 866 echo
 867 echo OpenOCD configuration summary
 868 echo --------------------------------------------------
 869 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 870         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 871         LIBGPIOD_ADAPTERS,
 872         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS,
 873         OPTIONAL_LIBRARIES],
 874         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 875         AS_CASE([$ADAPTER_VAR([adapter])],
 876                 [auto], [
 877                         echo "$s"yes '(auto)'
 878                 ],
 879                 [yes], [
 880                         echo "$s"yes
 881                 ],
 882                 [no], [
 883                         echo "$s"no
 884         ])
 885 ])
 886 echo
 887
 888 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 889   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 890   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 891   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 892   echo
 893 ])
 894
 895 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 896   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 897   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 898   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 899   echo 'Mailing List.'
 900   echo
 901 ])
 902
 903 AS_IF([test "x$build_ioutil" = "xyes"], [
 904   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 905   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 906   echo 'release. If you regularly depend on this functionality, please report to the'
 907   echo 'OpenOCD Mailing List.'
 908   echo
 909 ])