configure.ac

   1 AC_PREREQ([2.69])
   2 AC_INIT([openocd], [0.11.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5 AC_CONFIG_AUX_DIR([.])
   6
   7 m4_include([config_subdir.m4])dnl
   8
   9 # check for makeinfo before calling AM_INIT_AUTOMAKE
  10 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  11 AS_IF([test "x$MAKEINFO" = "x"], [
  12   MAKEINFO='echo makeinfo missing; true'
  13   AC_MSG_WARN([Info documentation will not be built.])
  14 ])
  15 AC_SUBST([MAKEINFO])
  16
  17 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20 AH_BOTTOM([
  21 #include <helper/system.h>
  22 #include <helper/types.h>
  23 #include <helper/replacements.h>
  24 ])
  25
  26 AC_LANG([C])
  27 AC_PROG_CC
  28 # autoconf 2.70 obsoletes AC_PROG_CC_C99 and includes it in AC_PROG_CC
  29 m4_version_prereq([2.70],[],[AC_PROG_CC_C99])
  30 AM_PROG_CC_C_O
  31 AC_PROG_RANLIB
  32 PKG_PROG_PKG_CONFIG([0.23])
  33
  34 dnl disable checks for C++, Fortran and GNU Java Compiler
  35 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  36 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  37 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  38 AC_DISABLE_SHARED
  39 LT_INIT
  40 AC_SUBST([LIBTOOL_DEPS])
  41
  42 dnl configure checks required for Jim files (these are obsolete w/ C99)
  43 AC_C_CONST
  44 AC_TYPE_LONG_LONG_INT
  45
  46 AC_SEARCH_LIBS([ioperm], [ioperm])
  47 AC_SEARCH_LIBS([dlopen], [dl])
  48 AC_SEARCH_LIBS([openpty], [util])
  49
  50 AC_CHECK_HEADERS([sys/socket.h])
  51 AC_CHECK_HEADERS([elf.h])
  52 AC_CHECK_HEADERS([dirent.h])
  53 AC_CHECK_HEADERS([fcntl.h])
  54 AC_CHECK_HEADERS([malloc.h])
  55 AC_CHECK_HEADERS([netdb.h])
  56 AC_CHECK_HEADERS([poll.h])
  57 AC_CHECK_HEADERS([pthread.h])
  58 AC_CHECK_HEADERS([strings.h])
  59 AC_CHECK_HEADERS([sys/ioctl.h])
  60 AC_CHECK_HEADERS([sys/param.h])
  61 AC_CHECK_HEADERS([sys/select.h])
  62 AC_CHECK_HEADERS([sys/stat.h])
  63 AC_CHECK_HEADERS([sys/sysctl.h])
  64 AC_CHECK_HEADERS([sys/time.h])
  65 AC_CHECK_HEADERS([sys/types.h])
  66 AC_CHECK_HEADERS([unistd.h])
  67 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  68 #include <stdio.h>
  69 #ifdef STDC_HEADERS
  70 # include <stdlib.h>
  71 # include <stddef.h>
  72 #else
  73 # ifdef HAVE_STDLIB_H
  74 #  include <stdlib.h>
  75 # endif
  76 #endif
  77 #ifdef HAVE_SYS_SOCKET_H
  78 # include <sys/socket.h>
  79 #endif
  80 ])
  81
  82 AC_HEADER_ASSERT
  83 AC_HEADER_STDBOOL
  84
  85 AC_C_BIGENDIAN
  86
  87 AC_CHECK_FUNCS([strndup])
  88 AC_CHECK_FUNCS([strnlen])
  89 AC_CHECK_FUNCS([gettimeofday])
  90 AC_CHECK_FUNCS([usleep])
  91 AC_CHECK_FUNCS([vasprintf])
  92 AC_CHECK_FUNCS([realpath])
  93
  94 # guess-rev.sh only exists in the repository, not in the released archives
  95 AC_MSG_CHECKING([whether to build a release])
  96 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  97   build_release=no
  98 ], [
  99   build_release=yes
 100 ])
 101 AC_MSG_RESULT([$build_release])
 102
 103 # Adapter drivers
 104 # 1st column -- configure option
 105 # 2nd column -- description
 106 # 3rd column -- symbol used for both config.h and automake
 107 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 108 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 109 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 110 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 111 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 112
 113 m4_define([USB1_ADAPTERS],
 114         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 115         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 116         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 117         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 118         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 119         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 120         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 121         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 122         [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
 123         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 124         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 125         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 126         [[aice], [Andes JTAG Programmer], [AICE]]])
 127
 128 m4_define([USB0_ADAPTERS],
 129         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 130         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 131
 132 m4_define([HIDAPI_ADAPTERS],
 133         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
 134         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 135
 136 m4_define([HIDAPI_USB1_ADAPTERS],
 137         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 138
 139 m4_define([LIBFTDI_ADAPTERS],
 140         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 141         [[presto], [ASIX Presto Adapter], [PRESTO]]])
 142
 143 m4_define([LIBFTDI_USB1_ADAPTERS],
 144         [[[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 145
 146 m4_define([LIBGPIOD_ADAPTERS],
 147         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 148
 149 m4_define([LIBJAYLINK_ADAPTERS],
 150         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 151
 152 m4_define([PCIE_ADAPTERS],
 153         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 154
 155 m4_define([OPTIONAL_LIBRARIES],
 156         [[[capstone], [Use Capstone disassembly framework], []]])
 157
 158 AC_ARG_ENABLE([doxygen-html],
 159   AS_HELP_STRING([--disable-doxygen-html],
 160     [Disable building Doxygen manual as HTML.]),
 161   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 162 AC_SUBST([doxygen_as_html])
 163 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 164 AC_MSG_RESULT([$doxygen_as_html])
 165
 166 AC_ARG_ENABLE([doxygen-pdf],
 167   AS_HELP_STRING([--enable-doxygen-pdf],
 168     [Enable building Doxygen manual as PDF.]),
 169   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 170 AC_SUBST([doxygen_as_pdf])
 171 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 172 AC_MSG_RESULT([$doxygen_as_pdf])
 173
 174 AC_ARG_ENABLE([gccwarnings],
 175   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 176   [gcc_warnings=$enableval], [gcc_warnings=yes])
 177
 178 AC_ARG_ENABLE([wextra],
 179   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 180   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 181
 182 AC_ARG_ENABLE([werror],
 183   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 184   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 185
 186 # set default verbose options, overridden by following options
 187 debug_usb_io=no
 188 debug_usb_comms=no
 189
 190 AC_ARG_ENABLE([verbose],
 191   AS_HELP_STRING([--enable-verbose],
 192       [Enable verbose JTAG I/O messages (for debugging).]),
 193   [
 194   debug_usb_io=$enableval
 195   debug_usb_comms=$enableval
 196   ], [])
 197
 198 AC_ARG_ENABLE([verbose_usb_io],
 199   AS_HELP_STRING([--enable-verbose-usb-io],
 200       [Enable verbose USB I/O messages (for debugging)]),
 201   [debug_usb_io=$enableval], [])
 202
 203 AC_ARG_ENABLE([verbose_usb_comms],
 204   AS_HELP_STRING([--enable-verbose-usb-comms],
 205       [Enable verbose USB communication messages (for debugging)]),
 206   [debug_usb_comms=$enableval], [])
 207
 208 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 209 AC_MSG_RESULT([$debug_usb_io])
 210 AS_IF([test "x$debug_usb_io" = "xyes"], [
 211   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 212 ])
 213
 214 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 215 AC_MSG_RESULT([$debug_usb_comms])
 216 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 217   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 218 ])
 219
 220 debug_malloc=no
 221 AC_ARG_ENABLE([malloc_logging],
 222   AS_HELP_STRING([--enable-malloc-logging],
 223       [Include free space in logging messages (requires malloc.h).]),
 224   [debug_malloc=$enableval], [])
 225
 226 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 227 AC_MSG_RESULT([$debug_malloc])
 228 AS_IF([test "x$debug_malloc" = "xyes"], [
 229   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 230 ])
 231
 232 AC_ARG_ENABLE([dummy],
 233   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 234   [build_dummy=$enableval], [build_dummy=no])
 235
 236 AC_ARG_ENABLE([rshim],
 237   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 238   [build_rshim=$enableval], [build_rshim=no])
 239
 240 m4_define([AC_ARG_ADAPTERS], [
 241   m4_foreach([adapter], [$1],
 242         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 243                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 244                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 245                 [], [ADAPTER_VAR([adapter])=$2])
 246   ])
 247 ])
 248
 249 AC_ARG_ADAPTERS([
 250   USB1_ADAPTERS,
 251   USB0_ADAPTERS,
 252   HIDAPI_ADAPTERS,
 253   HIDAPI_USB1_ADAPTERS,
 254   LIBFTDI_ADAPTERS,
 255   LIBFTDI_USB1_ADAPTERS
 256   LIBGPIOD_ADAPTERS,
 257   LIBJAYLINK_ADAPTERS
 258   ],[auto])
 259
 260 AC_ARG_ENABLE([parport],
 261   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 262   [build_parport=$enableval], [build_parport=no])
 263
 264 AC_ARG_ENABLE([parport_ppdev],
 265   AS_HELP_STRING([--disable-parport-ppdev],
 266       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 267     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 268
 269 AC_ARG_ENABLE([parport_giveio],
 270     AS_HELP_STRING([--enable-parport-giveio],
 271       [Enable use of giveio for parport (for CygWin only)]),
 272     [parport_use_giveio=$enableval], [parport_use_giveio=])
 273
 274 AC_ARG_ENABLE([jtag_vpi],
 275   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 276   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 277
 278 AC_ARG_ENABLE([jtag_dpi],
 279   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 280   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 281
 282 AC_ARG_ENABLE([amtjtagaccel],
 283   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 284   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 285
 286 AC_ARG_ENABLE([zy1000_master],
 287   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 288   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 289
 290 AC_ARG_ENABLE([zy1000],
 291   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 292   [build_zy1000=$enableval], [build_zy1000=no])
 293
 294 AS_CASE(["${host_cpu}"],
 295   [arm*|aarch64], [
 296     AC_ARG_ENABLE([bcm2835gpio],
 297       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 298       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 299     AC_ARG_ENABLE([imx_gpio],
 300       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 301       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 302   ],
 303   [
 304     build_bcm2835gpio=no
 305     build_imx_gpio=no
 306 ])
 307
 308 AS_CASE(["${host_cpu}"],
 309   [arm*], [
 310     AC_ARG_ENABLE([ep93xx],
 311       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 312       [build_ep93xx=$enableval], [build_ep93xx=no])
 313
 314     AC_ARG_ENABLE([at91rm9200],
 315       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 316       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 317   ],
 318   [
 319     build_ep93xx=no
 320     build_at91rm9200=no
 321 ])
 322
 323 AC_ARG_ENABLE([gw16012],
 324   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 325   [build_gw16012=$enableval], [build_gw16012=no])
 326
 327 AC_ARG_ENABLE([buspirate],
 328   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 329   [build_buspirate=$enableval], [build_buspirate=no])
 330
 331 AC_ARG_ENABLE([sysfsgpio],
 332   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 333   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 334
 335 AC_ARG_ENABLE([xlnx_pcie_xvc],
 336   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 337   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 338
 339 AS_CASE([$host_os],
 340   [linux*], [],
 341   [
 342     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 343       AC_MSG_ERROR([sysfsgpio is only available on linux])
 344     ])
 345
 346     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 347       AC_MSG_ERROR([linuxgpiod is only available on linux])
 348     ])
 349
 350     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 351       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 352     ])
 353
 354     AS_CASE([$host_os], [freebsd*], [],
 355     [
 356       AS_IF([test "x$build_rshim" = "xyes"], [
 357         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 358       ])
 359     ])
 360 ])
 361
 362 AC_ARG_ENABLE([minidriver_dummy],
 363   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 364   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 365
 366 AC_ARG_ENABLE([internal-jimtcl],
 367   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 368   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 369
 370 AC_ARG_ENABLE([internal-libjaylink],
 371   AS_HELP_STRING([--disable-internal-libjaylink],
 372   [Disable building internal libjaylink]),
 373   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 374
 375 build_minidriver=no
 376 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 377 AS_IF([test "x$build_zy1000" = "xyes"], [
 378   AS_IF([test "x$build_minidriver" = "xyes"], [
 379     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 380   ])
 381   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 382       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 383   build_minidriver=yes
 384 ])
 385 AC_MSG_RESULT([$build_zy1000])
 386
 387 AC_ARG_ENABLE([remote-bitbang],
 388   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 389   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 390
 391 AC_MSG_CHECKING([whether to enable dummy minidriver])
 392 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 393   AS_IF([test "x$build_minidriver" = "xyes"], [
 394     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 395   ])
 396   build_minidriver=yes
 397   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 398   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 399       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 400 ])
 401 AC_MSG_RESULT([$build_minidriver_dummy])
 402
 403 AC_MSG_CHECKING([whether standard drivers can be built])
 404 AS_IF([test "x$build_minidriver" = "xyes"], [
 405   AC_MSG_RESULT([no])
 406   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 407   sleep 2
 408 ], [
 409   AC_MSG_RESULT([yes])
 410 ])
 411
 412 AS_CASE(["${host_cpu}"],
 413   [i?86|x86*], [],
 414   [
 415     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 416       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 417     ])
 418     parport_use_ppdev=yes
 419 ])
 420
 421 AS_CASE([$host],
 422   [*-cygwin*], [
 423     is_win32=yes
 424     parport_use_ppdev=no
 425
 426     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 427       [is_mingw=yes],[is_mingw=no])
 428     AS_IF([test "x$is_mingw" = "xyes"], [
 429       AS_IF([test "x$parport_use_giveio" = "xno"], [
 430         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 431       ])
 432       parport_use_giveio=yes
 433       is_cygwin=no
 434     ], [
 435       is_cygwin=yes
 436       # sys/io.h needed under cygwin for parport access
 437       AS_IF([test "x$build_parport" = "xyes"], [
 438         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 439       ])
 440     ])
 441   ],
 442   [*-mingw* | *-msys*], [
 443     is_mingw=yes
 444     is_win32=yes
 445     parport_use_ppdev=no
 446
 447     AS_IF([test "x$parport_use_giveio" = "xno"], [
 448       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 449     ])
 450     parport_use_giveio=yes
 451
 452     AS_IF([test "x$build_buspirate" = "xyes"], [
 453       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 454     ])
 455
 456     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 457   ],
 458   [*darwin*], [
 459     is_darwin=yes
 460
 461     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 462       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 463     ])
 464     parport_use_giveio=no
 465   ],
 466   [
 467     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 468       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 469     ])
 470     parport_use_giveio=no
 471 ])
 472
 473 AS_IF([test "x$is_cygwin" = "xyes"], [
 474     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 475 ], [
 476     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 477 ])
 478
 479 AS_IF([test "x$is_mingw" = "xyes"], [
 480     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 481 ], [
 482     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 483 ])
 484
 485 AS_IF([test "x$is_win32" = "xyes"], [
 486     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 487 ], [
 488     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 489 ])
 490
 491 AS_IF([test "x$is_darwin" = "xyes"], [
 492     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 493 ], [
 494     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 495 ])
 496
 497 AS_IF([test "x$build_parport" = "xyes"], [
 498   build_bitbang=yes
 499   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 500 ], [
 501   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 502 ])
 503
 504 AS_IF([test "x$build_rshim" = "xyes"], [
 505   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 506 ], [
 507   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 508 ])
 509
 510 AS_IF([test "x$build_dummy" = "xyes"], [
 511   build_bitbang=yes
 512   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 513 ], [
 514   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 515 ])
 516
 517 AS_IF([test "x$build_ep93xx" = "xyes"], [
 518   build_bitbang=yes
 519   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 520 ], [
 521   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 522 ])
 523
 524 AS_IF([test "x$build_zy1000" = "xyes"], [
 525   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 526 ], [
 527   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 528 ])
 529
 530 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 531   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 532 ], [
 533   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 534 ])
 535
 536 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 537   build_bitbang=yes
 538   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 539 ], [
 540   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 541 ])
 542
 543 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 544   build_bitbang=yes
 545   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 546 ], [
 547   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 548 ])
 549
 550 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 551   build_bitbang=yes
 552   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 553 ], [
 554   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 555 ])
 556
 557 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 558   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 559 ], [
 560   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 561 ])
 562
 563 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 564   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 565 ], [
 566   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 567 ])
 568
 569 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 570   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 571 ], [
 572   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 573 ])
 574
 575 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 576   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 577 ], [
 578   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 579 ])
 580
 581
 582 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 583   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 584 ], [
 585   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 586 ])
 587
 588 AS_IF([test "x$build_gw16012" = "xyes"], [
 589   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 590 ], [
 591   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 592 ])
 593
 594 AS_IF([test "x$build_buspirate" = "xyes"], [
 595   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 596 ], [
 597   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 598 ])
 599
 600 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 601   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 602     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 603   ], [
 604     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 605   ])
 606 ])
 607
 608 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 609   build_bitbang=yes
 610   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 611 ], [
 612   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 613 ])
 614
 615 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 616   build_bitbang=yes
 617   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 618 ], [
 619   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 620 ])
 621
 622 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 623   build_xlnx_pcie_xvc=yes
 624   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 625 ], [
 626   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 627 ])
 628
 629 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 630         use_libusb1=yes
 631         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 632         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 633                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 634                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 635         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 636         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 637         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 638                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 639   ], [
 640         use_libusb1=no
 641         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 642 ])
 643
 644 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 645
 646 AC_ARG_WITH([capstone],
 647                 AS_HELP_STRING([--with-capstone], [Use Capstone disassembly library (default=auto)])
 648         , [
 649                 enable_capstone=$withval
 650         ], [
 651                 enable_capstone=auto
 652 ])
 653
 654 AS_IF([test "x$enable_capstone" != xno], [
 655         PKG_CHECK_MODULES([CAPSTONE], [capstone], [
 656                 AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have Capstone disassembly framework.])
 657         ], [
 658                 AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have Capstone disassembly framework.])
 659                 if test "x$enable_capstone" != xauto; then
 660                         AC_MSG_ERROR([--with-capstone was given, but test for Capstone failed])
 661                 fi
 662                 enable_capstone=no
 663         ])
 664 ])
 665
 666 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 667         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 668                 use_hidapi=yes
 669                 break
 670         ],[
 671                 use_hidapi=no
 672         ])
 673 done
 674
 675 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 676         use_libftdi=yes
 677         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 678                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 679   ], [
 680         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 681 ])
 682
 683 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 684
 685 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 686         [use_libjaylink=yes], [use_libjaylink=no])
 687
 688 m4_define([PROCESS_ADAPTERS], [
 689   m4_foreach([adapter], [$1], [
 690         AS_IF([test "x$build_zy1000" = "xyes"], [
 691                 ADAPTER_VAR([adapter])=no
 692         ])
 693         AS_IF([test $2], [
 694                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 695                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 696                 ], [
 697                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 698                 ])
 699         ], [
 700                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 701                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 702                 ])
 703                 ADAPTER_VAR([adapter])=no
 704         ])
 705         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 706   ])
 707 ])
 708
 709 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 710 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 711 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 712 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 713 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 714 PROCESS_ADAPTERS([LIBFTDI_USB1_ADAPTERS], ["x$use_libftdi" = "xyes" -a "x$use_libusb1" = "xyes"], [libftdi and libusb-1.x])
 715 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 716 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 717
 718 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 719   build_bitbang=yes
 720 ])
 721
 722 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 723         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 724         AM_CONDITIONAL([HLADAPTER], [true])
 725 ], [
 726         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 727         AM_CONDITIONAL([HLADAPTER], [false])
 728 ])
 729 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 730 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 731 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 732
 733 AS_IF([test "x$enable_jlink" != "xno"], [
 734   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 735     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 736       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 737                 [--enable-subproject-build])
 738     ], [
 739       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 740     ])
 741   ])
 742 ])
 743
 744 # Presto needs the bitq module
 745 AS_IF([test "x$enable_presto" != "xno"], [
 746   build_bitq=yes
 747 ])
 748
 749 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 750 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 751 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 752 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 753 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 754 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 755 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 756 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 757 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 758 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 759 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 760 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 761 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 762 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 763 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 764 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 765 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 766 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 767 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 768 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 769 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 770 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 771 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 772 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 773 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 774 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 775 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 776 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 777 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 778 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 779 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 780 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 781 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$enable_capstone" != "xno"])
 782
 783 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 784 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 785
 786 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 787 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 788
 789 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 790 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 791 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 792 #define _GNU_SOURCE
 793 #include <unistd.h>
 794 #include <stdlib.h>
 795   ]], [[char **ep = environ;]]
 796   )], [
 797     AC_MSG_RESULT([yes])
 798     has_environ=yes
 799   ], [
 800     AC_MSG_RESULT([no])
 801
 802     # Possibility #2: can environ be found in an available library?
 803     AC_MSG_CHECKING([for extern environ])
 804     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 805     extern char **environ;
 806     ]], [[char **ep = environ;]]
 807       )], [
 808         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 809         has_environ=yes
 810       ], [
 811         has_environ=no
 812       ])
 813     AC_MSG_RESULT([${has_environ}])
 814   ])
 815
 816 AS_IF([test "x${has_environ}" != "xyes" ], [
 817   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 818 ])
 819
 820 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 821
 822 # set default gcc warnings
 823 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 824 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 825   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 826   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 827   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 828   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 829   GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
 830 ])
 831 AS_IF([test "x${gcc_werror}" = "xyes"], [
 832   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 833 ])
 834
 835 # override default gcc cflags
 836 AS_IF([test "x$gcc_warnings" = "xyes"], [
 837   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 838 ])
 839
 840 AC_SUBST(EXTRA_DIST_NEWS, ["$(echo $srcdir/NEWS-*)"])
 841
 842 AC_CONFIG_FILES([
 843   Makefile
 844 ])
 845 AC_OUTPUT
 846
 847 echo
 848 echo
 849 echo OpenOCD configuration summary
 850 echo --------------------------------------------------
 851 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 852         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 853         LIBFTDI_USB1_ADAPTERS,
 854         LIBGPIOD_ADAPTERS,
 855         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS,
 856         OPTIONAL_LIBRARIES],
 857         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 858         AS_CASE([$ADAPTER_VAR([adapter])],
 859                 [auto], [
 860                         echo "$s"yes '(auto)'
 861                 ],
 862                 [yes], [
 863                         echo "$s"yes
 864                 ],
 865                 [no], [
 866                         echo "$s"no
 867         ])
 868 ])
 869 echo
 870
 871 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 872   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 873   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 874   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 875   echo 'Mailing List.'
 876   echo
 877 ])