configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.11.0-rc1],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5 AC_CONFIG_AUX_DIR([.])
   6
   7 m4_include([config_subdir.m4])dnl
   8
   9 # check for makeinfo before calling AM_INIT_AUTOMAKE
  10 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  11 AS_IF([test "x$MAKEINFO" = "x"], [
  12   MAKEINFO='echo makeinfo missing; true'
  13   AC_MSG_WARN([Info documentation will not be built.])
  14 ])
  15 AC_SUBST([MAKEINFO])
  16
  17 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20 AH_BOTTOM([
  21 #include <helper/system.h>
  22 #include <helper/types.h>
  23 #include <helper/replacements.h>
  24 ])
  25
  26 AC_LANG([C])
  27 AC_PROG_CC
  28 AC_PROG_CC_C99
  29 AM_PROG_CC_C_O
  30 AC_PROG_RANLIB
  31 PKG_PROG_PKG_CONFIG([0.23])
  32
  33 dnl disable checks for C++, Fortran and GNU Java Compiler
  34 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  36 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  37 AC_DISABLE_SHARED
  38 LT_INIT
  39 AC_SUBST([LIBTOOL_DEPS])
  40
  41 dnl configure checks required for Jim files (these are obsolete w/ C99)
  42 AC_C_CONST
  43 AC_TYPE_LONG_LONG_INT
  44
  45 AC_SEARCH_LIBS([ioperm], [ioperm])
  46 AC_SEARCH_LIBS([dlopen], [dl])
  47 AC_SEARCH_LIBS([openpty], [util])
  48
  49 AC_CHECK_HEADERS([sys/socket.h])
  50 AC_CHECK_HEADERS([elf.h])
  51 AC_CHECK_HEADERS([dirent.h])
  52 AC_CHECK_HEADERS([fcntl.h])
  53 AC_CHECK_HEADERS([malloc.h])
  54 AC_CHECK_HEADERS([netdb.h])
  55 AC_CHECK_HEADERS([poll.h])
  56 AC_CHECK_HEADERS([pthread.h])
  57 AC_CHECK_HEADERS([strings.h])
  58 AC_CHECK_HEADERS([sys/ioctl.h])
  59 AC_CHECK_HEADERS([sys/param.h])
  60 AC_CHECK_HEADERS([sys/select.h])
  61 AC_CHECK_HEADERS([sys/stat.h])
  62 AC_CHECK_HEADERS([sys/sysctl.h])
  63 AC_CHECK_HEADERS([sys/time.h])
  64 AC_CHECK_HEADERS([sys/types.h])
  65 AC_CHECK_HEADERS([unistd.h])
  66 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  67 #include <stdio.h>
  68 #ifdef STDC_HEADERS
  69 # include <stdlib.h>
  70 # include <stddef.h>
  71 #else
  72 # ifdef HAVE_STDLIB_H
  73 #  include <stdlib.h>
  74 # endif
  75 #endif
  76 #ifdef HAVE_SYS_SOCKET_H
  77 # include <sys/socket.h>
  78 #endif
  79 ])
  80
  81 AC_HEADER_ASSERT
  82 AC_HEADER_STDBOOL
  83 AC_HEADER_TIME
  84
  85 AC_C_BIGENDIAN
  86
  87 AC_CHECK_FUNCS([strndup])
  88 AC_CHECK_FUNCS([strnlen])
  89 AC_CHECK_FUNCS([gettimeofday])
  90 AC_CHECK_FUNCS([usleep])
  91 AC_CHECK_FUNCS([vasprintf])
  92 AC_CHECK_FUNCS([realpath])
  93
  94 # guess-rev.sh only exists in the repository, not in the released archives
  95 AC_MSG_CHECKING([whether to build a release])
  96 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  97   build_release=no
  98 ], [
  99   build_release=yes
 100 ])
 101 AC_MSG_RESULT([$build_release])
 102
 103 # Adapter drivers
 104 # 1st column -- configure option
 105 # 2nd column -- description
 106 # 3rd column -- symbol used for both config.h and automake
 107 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 108 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 109 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 110 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 111 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 112
 113 m4_define([USB1_ADAPTERS],
 114         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 115         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 116         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 117         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 118         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 119         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 120         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 121         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 122         [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
 123         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 124         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 125         [[aice], [Andes JTAG Programmer], [AICE]]])
 126
 127 m4_define([USB0_ADAPTERS],
 128         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 129         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 130         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 131
 132 m4_define([HIDAPI_ADAPTERS],
 133         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
 134         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 135
 136 m4_define([HIDAPI_USB1_ADAPTERS],
 137         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 138
 139 m4_define([LIBFTDI_ADAPTERS],
 140         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 141         [[presto], [ASIX Presto Adapter], [PRESTO]],
 142         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 143
 144 m4_define([LIBGPIOD_ADAPTERS],
 145         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 146
 147 m4_define([LIBJAYLINK_ADAPTERS],
 148         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 149
 150 m4_define([PCIE_ADAPTERS],
 151         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 152
 153
 154 AC_ARG_ENABLE([doxygen-html],
 155   AS_HELP_STRING([--disable-doxygen-html],
 156     [Disable building Doxygen manual as HTML.]),
 157   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 158 AC_SUBST([doxygen_as_html])
 159 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 160 AC_MSG_RESULT([$doxygen_as_html])
 161
 162 AC_ARG_ENABLE([doxygen-pdf],
 163   AS_HELP_STRING([--enable-doxygen-pdf],
 164     [Enable building Doxygen manual as PDF.]),
 165   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 166 AC_SUBST([doxygen_as_pdf])
 167 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 168 AC_MSG_RESULT([$doxygen_as_pdf])
 169
 170 AC_ARG_ENABLE([gccwarnings],
 171   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 172   [gcc_warnings=$enableval], [gcc_warnings=yes])
 173
 174 AC_ARG_ENABLE([wextra],
 175   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 176   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 177
 178 AC_ARG_ENABLE([werror],
 179   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 180   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 181
 182 # set default verbose options, overridden by following options
 183 debug_usb_io=no
 184 debug_usb_comms=no
 185
 186 AC_ARG_ENABLE([verbose],
 187   AS_HELP_STRING([--enable-verbose],
 188       [Enable verbose JTAG I/O messages (for debugging).]),
 189   [
 190   debug_usb_io=$enableval
 191   debug_usb_comms=$enableval
 192   ], [])
 193
 194 AC_ARG_ENABLE([verbose_usb_io],
 195   AS_HELP_STRING([--enable-verbose-usb-io],
 196       [Enable verbose USB I/O messages (for debugging)]),
 197   [debug_usb_io=$enableval], [])
 198
 199 AC_ARG_ENABLE([verbose_usb_comms],
 200   AS_HELP_STRING([--enable-verbose-usb-comms],
 201       [Enable verbose USB communication messages (for debugging)]),
 202   [debug_usb_comms=$enableval], [])
 203
 204 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 205 AC_MSG_RESULT([$debug_usb_io])
 206 AS_IF([test "x$debug_usb_io" = "xyes"], [
 207   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 208 ])
 209
 210 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 211 AC_MSG_RESULT([$debug_usb_comms])
 212 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 213   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 214 ])
 215
 216 debug_malloc=no
 217 AC_ARG_ENABLE([malloc_logging],
 218   AS_HELP_STRING([--enable-malloc-logging],
 219       [Include free space in logging messages (requires malloc.h).]),
 220   [debug_malloc=$enableval], [])
 221
 222 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 223 AC_MSG_RESULT([$debug_malloc])
 224 AS_IF([test "x$debug_malloc" = "xyes"], [
 225   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 226 ])
 227
 228 AC_ARG_ENABLE([dummy],
 229   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 230   [build_dummy=$enableval], [build_dummy=no])
 231
 232 AC_ARG_ENABLE([rshim],
 233   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 234   [build_rshim=$enableval], [build_rshim=no])
 235
 236 m4_define([AC_ARG_ADAPTERS], [
 237   m4_foreach([adapter], [$1],
 238         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 239                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 240                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 241                 [], [ADAPTER_VAR([adapter])=$2])
 242   ])
 243 ])
 244
 245 AC_ARG_ADAPTERS([
 246   USB1_ADAPTERS,
 247   USB0_ADAPTERS,
 248   HIDAPI_ADAPTERS,
 249   HIDAPI_USB1_ADAPTERS,
 250   LIBFTDI_ADAPTERS,
 251   LIBGPIOD_ADAPTERS,
 252   LIBJAYLINK_ADAPTERS
 253   ],[auto])
 254
 255 AC_ARG_ENABLE([parport],
 256   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 257   [build_parport=$enableval], [build_parport=no])
 258
 259 AC_ARG_ENABLE([parport_ppdev],
 260   AS_HELP_STRING([--disable-parport-ppdev],
 261       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 262     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 263
 264 AC_ARG_ENABLE([parport_giveio],
 265     AS_HELP_STRING([--enable-parport-giveio],
 266       [Enable use of giveio for parport (for CygWin only)]),
 267     [parport_use_giveio=$enableval], [parport_use_giveio=])
 268
 269 AC_ARG_ENABLE([jtag_vpi],
 270   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 271   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 272
 273 AC_ARG_ENABLE([jtag_dpi],
 274   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 275   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 276
 277 AC_ARG_ENABLE([amtjtagaccel],
 278   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 279   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 280
 281 AC_ARG_ENABLE([zy1000_master],
 282   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 283   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 284
 285 AC_ARG_ENABLE([zy1000],
 286   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 287   [build_zy1000=$enableval], [build_zy1000=no])
 288
 289 AC_ARG_ENABLE([ioutil],
 290   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 291   [build_ioutil=$enableval], [build_ioutil=no])
 292
 293 AS_CASE(["${host_cpu}"],
 294   [arm*|aarch64], [
 295     AC_ARG_ENABLE([bcm2835gpio],
 296       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 297       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 298     AC_ARG_ENABLE([imx_gpio],
 299       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 300       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 301   ],
 302   [
 303     build_bcm2835gpio=no
 304     build_imx_gpio=no
 305 ])
 306
 307 AS_CASE(["${host_cpu}"],
 308   [arm*], [
 309     AC_ARG_ENABLE([ep93xx],
 310       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 311       [build_ep93xx=$enableval], [build_ep93xx=no])
 312
 313     AC_ARG_ENABLE([at91rm9200],
 314       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 315       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 316   ],
 317   [
 318     build_ep93xx=no
 319     build_at91rm9200=no
 320 ])
 321
 322 AC_ARG_ENABLE([gw16012],
 323   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 324   [build_gw16012=$enableval], [build_gw16012=no])
 325
 326 AC_ARG_ENABLE([oocd_trace],
 327   AS_HELP_STRING([--enable-oocd_trace],
 328   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 329   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 330
 331 AC_ARG_ENABLE([buspirate],
 332   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 333   [build_buspirate=$enableval], [build_buspirate=no])
 334
 335 AC_ARG_ENABLE([sysfsgpio],
 336   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 337   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 338
 339 AC_ARG_ENABLE([xlnx_pcie_xvc],
 340   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 341   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 342
 343 AS_CASE([$host_os],
 344   [linux*], [],
 345   [
 346     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 347       AC_MSG_ERROR([sysfsgpio is only available on linux])
 348     ])
 349
 350     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 351       AC_MSG_ERROR([linuxgpiod is only available on linux])
 352     ])
 353
 354     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 355       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 356     ])
 357
 358     AS_CASE([$host_os], [freebsd*], [],
 359     [
 360       AS_IF([test "x$build_rshim" = "xyes"], [
 361         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 362       ])
 363     ])
 364 ])
 365
 366 AC_ARG_ENABLE([minidriver_dummy],
 367   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 368   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 369
 370 AC_ARG_ENABLE([internal-jimtcl],
 371   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 372   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 373
 374 AC_ARG_ENABLE([internal-libjaylink],
 375   AS_HELP_STRING([--disable-internal-libjaylink],
 376   [Disable building internal libjaylink]),
 377   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 378
 379 build_minidriver=no
 380 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 381 AS_IF([test "x$build_zy1000" = "xyes"], [
 382   AS_IF([test "x$build_minidriver" = "xyes"], [
 383     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 384   ])
 385   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 386       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 387   build_minidriver=yes
 388 ])
 389 AC_MSG_RESULT([$build_zy1000])
 390
 391 AC_ARG_ENABLE([remote-bitbang],
 392   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 393   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 394
 395 AC_MSG_CHECKING([whether to enable dummy minidriver])
 396 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 397   AS_IF([test "x$build_minidriver" = "xyes"], [
 398     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 399   ])
 400   build_minidriver=yes
 401   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 402   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 403       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 404 ])
 405 AC_MSG_RESULT([$build_minidriver_dummy])
 406
 407 AC_MSG_CHECKING([whether standard drivers can be built])
 408 AS_IF([test "x$build_minidriver" = "xyes"], [
 409   AC_MSG_RESULT([no])
 410   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 411   sleep 2
 412 ], [
 413   AC_MSG_RESULT([yes])
 414 ])
 415
 416 AS_CASE(["${host_cpu}"],
 417   [i?86|x86*], [],
 418   [
 419     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 420       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 421     ])
 422     parport_use_ppdev=yes
 423 ])
 424
 425 AS_CASE([$host],
 426   [*-cygwin*], [
 427     is_win32=yes
 428     parport_use_ppdev=no
 429
 430     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 431       [is_mingw=yes],[is_mingw=no])
 432     AS_IF([test "x$is_mingw" = "xyes"], [
 433       AS_IF([test "x$parport_use_giveio" = "xno"], [
 434         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 435       ])
 436       parport_use_giveio=yes
 437       is_cygwin=no
 438     ], [
 439       is_cygwin=yes
 440       # sys/io.h needed under cygwin for parport access
 441       AS_IF([test "x$build_parport" = "xyes"], [
 442         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 443       ])
 444     ])
 445   ],
 446   [*-mingw* | *-msys*], [
 447     is_mingw=yes
 448     is_win32=yes
 449     parport_use_ppdev=no
 450
 451     AS_IF([test "x$parport_use_giveio" = "xno"], [
 452       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 453     ])
 454     parport_use_giveio=yes
 455
 456     AS_IF([test "x$build_buspirate" = "xyes"], [
 457       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 458     ])
 459
 460     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 461   ],
 462   [*darwin*], [
 463     is_darwin=yes
 464
 465     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 466       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 467     ])
 468     parport_use_giveio=no
 469   ],
 470   [
 471     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 472       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 473     ])
 474     parport_use_giveio=no
 475 ])
 476
 477 AS_IF([test "x$is_cygwin" = "xyes"], [
 478     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 479 ], [
 480     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 481 ])
 482
 483 AS_IF([test "x$is_mingw" = "xyes"], [
 484     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 485 ], [
 486     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 487 ])
 488
 489 AS_IF([test "x$is_win32" = "xyes"], [
 490     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 491 ], [
 492     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 493 ])
 494
 495 AS_IF([test "x$is_darwin" = "xyes"], [
 496     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 497 ], [
 498     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 499 ])
 500
 501 AS_IF([test "x$build_parport" = "xyes"], [
 502   build_bitbang=yes
 503   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 504 ], [
 505   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 506 ])
 507
 508 AS_IF([test "x$build_rshim" = "xyes"], [
 509   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 510 ], [
 511   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 512 ])
 513
 514 AS_IF([test "x$build_dummy" = "xyes"], [
 515   build_bitbang=yes
 516   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 517 ], [
 518   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 519 ])
 520
 521 AS_IF([test "x$build_ep93xx" = "xyes"], [
 522   build_bitbang=yes
 523   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 524 ], [
 525   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 526 ])
 527
 528 AS_IF([test "x$build_zy1000" = "xyes"], [
 529   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 530 ], [
 531   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 532 ])
 533
 534 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 535   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 536 ], [
 537   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 538 ])
 539
 540 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 541   build_bitbang=yes
 542   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 543 ], [
 544   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 545 ])
 546
 547 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 548   build_bitbang=yes
 549   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 550 ], [
 551   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 552 ])
 553
 554 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 555   build_bitbang=yes
 556   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 557 ], [
 558   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 559 ])
 560
 561 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 562   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 563 ], [
 564   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 565 ])
 566
 567 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 568   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 569 ], [
 570   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 571 ])
 572
 573 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 574   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 575 ], [
 576   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 577 ])
 578
 579 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 580   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 581 ], [
 582   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 583 ])
 584
 585
 586 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 587   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 588 ], [
 589   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 590 ])
 591
 592 AS_IF([test "x$build_gw16012" = "xyes"], [
 593   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 594 ], [
 595   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 596 ])
 597
 598 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 599   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 600 ], [
 601   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 602 ])
 603
 604 AS_IF([test "x$build_buspirate" = "xyes"], [
 605   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 606 ], [
 607   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 608 ])
 609
 610 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 611   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 612     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 613   ], [
 614     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 615   ])
 616 ])
 617
 618 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 619   build_bitbang=yes
 620   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 621 ], [
 622   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 623 ])
 624
 625 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 626   build_bitbang=yes
 627   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 628 ], [
 629   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 630 ])
 631
 632 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 633   build_xlnx_pcie_xvc=yes
 634   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 635 ], [
 636   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 637 ])
 638
 639 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 640         use_libusb1=yes
 641         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 642         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 643                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 644                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 645         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 646         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 647         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 648                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 649   ], [
 650         use_libusb1=no
 651         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 652 ])
 653
 654 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 655
 656 PKG_CHECK_MODULES([CAPSTONE], [capstone], [have_capstone=yes],
 657         [have_capstone=no])
 658
 659 AS_IF([test "x$have_capstone" = "xyes"], [
 660   AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have captone disassembly framework.])
 661 ], [
 662   AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have captone disassembly framework.])
 663 ])
 664
 665 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 666         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 667                 use_hidapi=yes
 668                 break
 669         ],[
 670                 use_hidapi=no
 671         ])
 672 done
 673
 674 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 675         use_libftdi=yes
 676         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 677                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 678   ], [
 679         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 680 ])
 681
 682 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 683
 684 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 685         [use_libjaylink=yes], [use_libjaylink=no])
 686
 687 m4_define([PROCESS_ADAPTERS], [
 688   m4_foreach([adapter], [$1], [
 689         AS_IF([test "x$build_zy1000" = "xyes"], [
 690                 ADAPTER_VAR([adapter])=no
 691         ])
 692         AS_IF([test $2], [
 693                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 694                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 695                 ], [
 696                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 697                 ])
 698         ], [
 699                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 700                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 701                 ])
 702                 ADAPTER_VAR([adapter])=no
 703         ])
 704         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 705   ])
 706 ])
 707
 708 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 709 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 710 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 711 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 712 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 713 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 714 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 715
 716 AS_IF([test "x$build_openjtag" = "xyes"], [
 717   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 718     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 719     build_openjtag=no
 720   ])
 721 ])
 722
 723 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 724   build_bitbang=yes
 725 ])
 726
 727 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 728         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 729         AM_CONDITIONAL([HLADAPTER], [true])
 730 ], [
 731         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 732         AM_CONDITIONAL([HLADAPTER], [false])
 733 ])
 734 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 735 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 736 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 737
 738 AS_IF([test "x$enable_jlink" != "xno"], [
 739   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 740     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 741       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 742                 [--enable-subproject-build])
 743     ], [
 744       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 745     ])
 746   ])
 747 ])
 748
 749 # Presto needs the bitq module
 750 AS_IF([test "x$enable_presto" != "xno"], [
 751   build_bitq=yes
 752 ])
 753
 754 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 755 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 756 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 757 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 758 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 759 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 760 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 761 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 762 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 763 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 764 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 765 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 766 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 767 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes" -o "x$build_jtag_dpi" = "xyes"])
 768 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 769 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 770 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 771 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 772 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 773 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 774 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 775 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 776 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 777 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 778 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 779 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 780 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 781 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 782 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 783 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 784 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 785 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 786 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 787 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 788 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$have_capstone" = "xyes"])
 789
 790 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 791 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 792
 793 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 794 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 795
 796 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 797 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 798 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 799 #define _GNU_SOURCE
 800 #include <unistd.h>
 801 #include <stdlib.h>
 802   ]], [[char **ep = environ;]]
 803   )], [
 804     AC_MSG_RESULT([yes])
 805     has_environ=yes
 806   ], [
 807     AC_MSG_RESULT([no])
 808
 809     # Possibility #2: can environ be found in an available library?
 810     AC_MSG_CHECKING([for extern environ])
 811     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 812     extern char **environ;
 813     ]], [[char **ep = environ;]]
 814       )], [
 815         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 816         has_environ=yes
 817       ], [
 818         has_environ=no
 819       ])
 820     AC_MSG_RESULT([${has_environ}])
 821   ])
 822
 823 AS_IF([test "x${has_environ}" != "xyes" ], [
 824   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 825 ])
 826
 827 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 828
 829 # set default gcc warnings
 830 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 831 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 832   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 833   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 834   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 835   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 836   GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
 837 ])
 838 AS_IF([test "x${gcc_werror}" = "xyes"], [
 839   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 840 ])
 841
 842 # override default gcc cflags
 843 AS_IF([test "x$gcc_warnings" = "xyes"], [
 844   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 845 ])
 846
 847 AC_CONFIG_FILES([
 848   Makefile
 849 ])
 850 AC_OUTPUT
 851
 852 echo
 853 echo
 854 echo OpenOCD configuration summary
 855 echo --------------------------------------------------
 856 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 857         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 858         LIBGPIOD_ADAPTERS,
 859         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 860         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 861         AS_CASE([$ADAPTER_VAR([adapter])],
 862                 [auto], [
 863                         echo "$s"yes '(auto)'
 864                 ],
 865                 [yes], [
 866                         echo "$s"yes
 867                 ],
 868                 [no], [
 869                         echo "$s"no
 870         ])
 871 ])
 872 echo
 873
 874 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 875   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 876   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 877   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 878   echo
 879 ])
 880
 881 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 882   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 883   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 884   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 885   echo 'Mailing List.'
 886   echo
 887 ])
 888
 889 AS_IF([test "x$build_ioutil" = "xyes"], [
 890   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 891   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 892   echo 'release. If you regularly depend on this functionality, please report to the'
 893   echo 'OpenOCD Mailing List.'
 894   echo
 895 ])