contrib/loaders/flash/msp432/msp432p401x/msp432p401x.lds

   1 /* SPDX-License-Identifier: BSD-3-Clause */
   2
   3 /******************************************************************************
   4 *
   5 * Copyright (C) 2012-2018 Texas Instruments Incorporated - http://www.ti.com/
   6 *
   7 ******************************************************************************/
   8
   9 MEMORY {
  10         MAIN_FLASH (RX) : ORIGIN = 0x00000000, LENGTH = 0x00040000
  11         INFO_FLASH (RX) : ORIGIN = 0x00200000, LENGTH = 0x00004000
  12         SRAM_CODE_0(RWX): ORIGIN = 0x01000000, LENGTH = 0x00000110
  13         SRAM_CODE_1(RWX): ORIGIN = 0x01000110, LENGTH = 0x00000030
  14         SRAM_CODE_2(RWX): ORIGIN = 0x01000150, LENGTH = 0x00000040
  15         SRAM_CODE_3(RWX): ORIGIN = 0x01000190, LENGTH = 0x00000F70
  16         SRAM_CODE_4(RWX): ORIGIN = 0x01001170, LENGTH = 0x00000200
  17         SRAM_DATA  (RW) : ORIGIN = 0x20002000, LENGTH = 0x00001000
  18 }
  19
  20 REGION_ALIAS("REGION_INTVECT", SRAM_CODE_0);
  21 REGION_ALIAS("REGION_RESET", SRAM_CODE_1);
  22 REGION_ALIAS("REGION_DESCRIPTOR", SRAM_CODE_2);
  23 REGION_ALIAS("REGION_TEXT", SRAM_CODE_3);
  24 REGION_ALIAS("REGION_BSS", SRAM_CODE_3);
  25 REGION_ALIAS("REGION_DATA", SRAM_DATA);
  26 REGION_ALIAS("REGION_STACK", SRAM_CODE_4);
  27 REGION_ALIAS("REGION_HEAP", SRAM_DATA);
  28 REGION_ALIAS("REGION_ARM_EXIDX", SRAM_CODE_3);
  29 REGION_ALIAS("REGION_ARM_EXTAB", SRAM_CODE_3);
  30
  31
  32 SECTIONS {
  33         /* section for the interrupt vector area */
  34         .intvecs : {
  35                 KEEP (*(.intvecs))
  36         } > REGION_INTVECT
  37
  38         PROVIDE (_vtable_base_address =
  39                 DEFINED(_vtable_base_address) ? _vtable_base_address : 0x20000000);
  40
  41         .vtable (_vtable_base_address) : AT (_vtable_base_address) {
  42                 KEEP (*(.vtable))
  43         } > REGION_DATA
  44
  45         .descriptor :{
  46                 FILL(0x00000000);
  47                 . = ORIGIN(REGION_DESCRIPTOR) + LENGTH(REGION_DESCRIPTOR) - 1;
  48                 BYTE(0x00);
  49                 __ROM_AT = .;
  50         } > REGION_DESCRIPTOR
  51
  52         .reset : {
  53                 KEEP(*(.reset))
  54         } > REGION_RESET AT> REGION_RESET
  55
  56         .text : {
  57                 CREATE_OBJECT_SYMBOLS
  58                 KEEP (*(.text))
  59                 *(.text.*)
  60                 . = ALIGN(0x4);
  61                 KEEP (*(.ctors))
  62                 . = ALIGN(0x4);
  63                 KEEP (*(.dtors))
  64                 . = ALIGN(0x4);
  65                 __init_array_start = .;
  66                 KEEP (*(.init_array*))
  67                 __init_array_end = .;
  68                 KEEP (*(.init))
  69                 KEEP (*(.fini*))
  70         } > REGION_TEXT AT> REGION_TEXT
  71
  72         .rodata : {
  73                 *(.rodata)
  74                 *(.rodata.*)
  75         } > REGION_TEXT AT> REGION_TEXT
  76
  77         .ARM.exidx : {
  78                 __exidx_start = .;
  79                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  80                 __exidx_end = .;
  81         } > REGION_ARM_EXIDX AT> REGION_ARM_EXIDX
  82
  83         .ARM.extab : {
  84                 KEEP (*(.ARM.extab* .gnu.linkonce.armextab.*))
  85         } > REGION_ARM_EXTAB AT> REGION_ARM_EXTAB
  86
  87         __etext = .;
  88
  89         .data : {
  90                 __data_load__ = LOADADDR (.data);
  91                 __data_start__ = .;
  92                 KEEP (*(.data))
  93                 KEEP (*(.data*))
  94                 . = ALIGN (4);
  95                 __data_end__ = .;
  96         } > REGION_DATA AT> REGION_TEXT
  97
  98         .bss : {
  99                 __bss_start__ = .;
 100                 *(.shbss)
 101                 KEEP (*(.bss))
 102                 *(.bss.*)
 103                 *(COMMON)
 104                 . = ALIGN (4);
 105                 __bss_end__ = .;
 106         } > REGION_BSS AT> REGION_BSS
 107
 108         .heap : {
 109                 __heap_start__ = .;
 110                 end = __heap_start__;
 111                 _end = end;
 112                 __end = end;
 113                 KEEP (*(.heap))
 114                 __heap_end__ = .;
 115                 __HeapLimit = __heap_end__;
 116         } > REGION_HEAP AT> REGION_HEAP
 117
 118         .stack (NOLOAD) : ALIGN(0x8) {
 119                 _stack = .;
 120                 KEEP(*(.stack))
 121         } > REGION_STACK AT> REGION_STACK
 122
 123         __stack_top = ORIGIN(REGION_STACK) + LENGTH(REGION_STACK);
 124         PROVIDE(__stack = __stack_top);
 125 }